使用依赖项指南¶
简介¶
项目经常依赖于其他项目、资产和工件。CMake 提供了多种方法将这些内容整合到构建中。项目和用户可以灵活地选择最适合其需求的方法。
将依赖项引入构建的主要方法是 find_package()
命令和 FetchContent
模块。FindPkgConfig
模块有时也会使用,尽管它缺乏其他两个模块的一些集成,并且在本指南中不再进一步讨论。
依赖项也可以通过自定义的 依赖项提供程序 来提供。这可能是第三方包管理器,也可能是开发人员实现的自定义代码。依赖项提供程序与上述主要方法协同工作,以扩展其灵活性。
使用预构建包和 find_package()
¶
项目所需的包可能已经构建完成,并且在用户系统的某个位置可用。该包可能是由 CMake 构建的,也可能完全使用了不同的构建系统。它甚至可能只是一组无需构建的文件集合。CMake 提供了 find_package()
命令来应对这些情况。它搜索众所周知的位置,以及项目或用户提供的其他提示和路径。它还支持包组件和可选包。结果变量被提供,以允许项目根据是否找到包或特定组件来定制其自身的行为。
在大多数情况下,项目通常应使用 基本签名。大多数时候,这将只涉及包名称、可能的版本约束,以及 REQUIRED
关键字(如果依赖项不是可选的)。也可以指定一组包组件。
find_package()
基本签名示例¶find_package(Catch2)
find_package(GTest REQUIRED)
find_package(Boost 1.79 COMPONENTS date_time)
find_package()
命令支持两种主要的方法来执行搜索
- 配置模式
使用此方法,命令查找通常由包本身提供的文件。这是两种方法中更可靠的一种,因为包的详细信息应始终与包同步。
- 模块模式
并非所有包都是 CMake 感知的。许多包不提供支持配置模式所需的文件。对于这种情况,可以单独提供 Find 模块文件,可以由项目提供,也可以由 CMake 提供。Find 模块通常是一种启发式实现,它知道包通常提供什么以及如何将该包呈现给项目。由于 Find 模块通常与包分开分发,因此它们不如配置模式可靠。它们通常是单独维护的,并且它们可能遵循不同的发布计划,因此它们很容易过时。
根据使用的参数,find_package()
可能会使用上述两种方法中的一种或两种。通过将选项限制为基本签名,配置模式和模块模式都可以用于满足依赖项。其他选项的存在可能会将调用限制为仅使用两种方法之一,从而可能降低命令查找依赖项的能力。有关此复杂主题的完整详细信息,请参阅 find_package()
文档。
对于这两种搜索方法,用户还可以在 cmake(1)
命令行或在 ccmake(1)
或 cmake-gui(1)
UI 工具中设置缓存变量,以影响和覆盖查找包的位置。有关如何设置缓存变量的更多信息,请参阅 用户交互指南。
配置文件包¶
第三方为 CMake 提供可执行文件、库、头文件和其他文件的首选方法是提供 配置文件。这些是随包一起提供的文本文件,它们定义了 CMake 目标、变量、命令等等。配置文件是一个普通的 CMake 脚本,由 find_package()
命令读取。
配置文件通常可以在名称与模式 lib/cmake/<PackageName>
匹配的目录中找到,尽管它们也可能位于其他位置(请参阅 配置模式搜索过程)。<PackageName>
通常是 find_package()
命令的第一个参数,它甚至可能是唯一的参数。也可以使用 NAMES
选项指定备用名称
find_package(SomeThing
NAMES
SameThingOtherName # Another name for the package
SomeThing # Also still look for its canonical name
)
配置文件必须命名为 <PackageName>Config.cmake
或 <LowercasePackageName>-config.cmake
(本指南的其余部分使用前者,但两者都受支持)。此文件是 CMake 包的入口点。一个单独的可选文件,名为 <PackageName>ConfigVersion.cmake
或 <LowercasePackageName>-config-version.cmake
,也可能存在于同一目录中。CMake 使用此文件来确定包的版本是否满足调用 find_package()
中包含的任何版本约束。即使存在 <PackageName>ConfigVersion.cmake
文件,在调用 find_package()
时,指定版本也是可选的。
如果找到 <PackageName>Config.cmake
文件并且满足任何版本约束,则 find_package()
命令会认为找到了包,并且假定整个包按设计完成。
可能存在其他文件,为您提供 CMake 命令或 导入目标 以供使用。CMake 不强制执行这些文件的任何命名约定。它们通过使用 CMake include()
命令与主要的 <PackageName>Config.cmake
文件相关联。<PackageName>Config.cmake
文件通常会为您包含这些文件,因此除了调用 find_package()
之外,它们通常不需要任何额外的步骤。
如果包的位置在 CMake 已知的目录 中,则 find_package()
调用应该成功。CMake 已知的目录是平台特定的。例如,使用标准系统包管理器安装在 Linux 上的包将在 /usr
前缀中自动找到。安装在 Windows 上的 Program Files
中的包也将类似地自动找到。
如果包位于 CMake 未知的位置,例如 /opt/mylib
或 $HOME/dev/prefix
,则在没有帮助的情况下将无法自动找到包。这是一种正常情况,CMake 提供了几种方法供用户指定在何处查找此类库。
CMAKE_PREFIX_PATH
变量可以在 调用 CMake 时设置。它被视为搜索 配置文件 的基本路径列表。安装在 /opt/somepackage
中的包通常会安装配置文件,例如 /opt/somepackage/lib/cmake/somePackage/SomePackageConfig.cmake
。在这种情况下,应将 /opt/somepackage
添加到 CMAKE_PREFIX_PATH
。
环境变量 CMAKE_PREFIX_PATH
也可以填充要搜索包的前缀。与 PATH
环境变量类似,这是一个列表,但它需要使用平台特定的环境变量列表项分隔符(Unix 上为 :
,Windows 上为 ;
)。
CMAKE_PREFIX_PATH
变量在需要指定多个前缀,或者同一前缀下有多个包可用时,提供了便利。包的路径也可以通过设置与 <PackageName>_DIR
匹配的变量来指定,例如 SomePackage_DIR
。请注意,这不是前缀,而应该是包含配置样式包文件的目录的完整路径,例如上述示例中的 /opt/somepackage/lib/cmake/SomePackage
。有关其他可以影响搜索的 CMake 变量和环境变量,请参阅 find_package()
文档。
查找模块文件¶
如果 FindSomePackage.cmake
文件可用,则即使包不提供配置文件,仍然可以使用 find_package()
命令找到它们。这些 Find 模块文件与配置文件的不同之处在于
Find 模块文件不应由包本身提供。
Find<PackageName>.cmake
文件的可用性并不表示包或包的任何特定部分可用。CMake 不会在
CMAKE_PREFIX_PATH
变量中指定的位置搜索Find<PackageName>.cmake
文件。相反,CMake 在CMAKE_MODULE_PATH
变量给出的位置搜索此类文件。用户通常在运行 CMake 时设置CMAKE_MODULE_PATH
,CMake 项目通常会附加到CMAKE_MODULE_PATH
,以允许使用本地 Find 模块文件。CMake 为一些
第三方包
提供了Find<PackageName>.cmake
文件。这些文件是 CMake 的维护负担,并且这些文件落后于与其关联的包的最新版本的情况并不少见。一般来说,新的 Find 模块不再添加到 CMake 中。项目应鼓励上游包尽可能提供配置文件。如果这样做不成功,项目应为包提供自己的 Find 模块。
有关如何编写 Find 模块文件的详细讨论,请参阅 Find 模块。
导入目标¶
配置文件和 Find 模块文件都可以定义 导入目标。这些目标通常具有 SomePrefix::ThingName
形式的名称。如果这些可用,项目应优先使用它们,而不是可能也提供的任何 CMake 变量。此类目标通常带有使用要求,并将头文件搜索路径、编译器定义等自动应用于链接到它们的其他目标(例如,使用 target_link_libraries()
)。这比尝试使用变量手动应用相同的内容更健壮且更方便。查看包或 Find 模块的文档,以了解它定义了哪些导入目标(如果有)。
导入目标还应封装任何特定于配置的路径。这包括二进制文件(库、可执行文件)的位置、编译器标志和任何其他依赖于配置的量。与配置文件相比,Find 模块在提供这些详细信息方面可能不太可靠。
查找第三方包并使用其中的库的完整示例如下所示
cmake_minimum_required(VERSION 3.10)
project(MyExeProject VERSION 1.0.0)
# Make project-provided Find modules available
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
find_package(SomePackage REQUIRED)
add_executable(MyExe main.cpp)
target_link_libraries(MyExe PRIVATE SomePrefix::LibName)
请注意,上面对 find_package()
的调用可以通过配置文件或 Find 模块来解析。它仅使用 基本签名 支持的基本参数。例如,${CMAKE_CURRENT_SOURCE_DIR}/cmake
目录中的 FindSomePackage.cmake
文件将允许 find_package()
命令使用模块模式成功运行。如果不存在此类模块文件,则将在系统中搜索配置文件。
使用 FetchContent
从源代码下载和构建¶
依赖项不一定必须预先构建才能与 CMake 一起使用。它们可以作为主项目的一部分从源代码构建。FetchContent
模块提供了下载内容(通常是源代码,但可以是任何内容)并将其添加到主项目的功能,如果依赖项也使用 CMake。依赖项的源代码将与项目的其余部分一起构建,就像源代码是项目自身源代码的一部分一样。
一般模式是项目应首先声明它要使用的所有依赖项,然后请求使它们可用。以下演示了该原则(有关更多信息,请参阅 示例)
include(FetchContent)
FetchContent_Declare(
googletest
GIT_REPOSITORY https://github.com/google/googletest.git
GIT_TAG 703bd9caab50b139428cea1aaff9974ebee5742e # release-1.10.0
)
FetchContent_Declare(
Catch2
GIT_REPOSITORY https://github.com/catchorg/Catch2.git
GIT_TAG 605a34765aa5d5ecbf476b4598a862ada971b0cc # v3.0.1
)
FetchContent_MakeAvailable(googletest Catch2)
支持各种下载方法,包括从 URL 下载和提取存档(支持一系列存档格式),以及包括 Git、Subversion 和 Mercurial 在内的多种存储库格式。自定义下载、更新和补丁命令也可用于支持任意用例。
当使用 FetchContent
将依赖项添加到项目时,项目链接到依赖项的目标,就像链接到项目中的任何其他目标一样。如果依赖项提供 SomePrefix::ThingName
形式的命名空间目标,则项目应链接到这些目标,而不是任何非命名空间目标。请参阅下一节,了解为什么建议这样做。
并非所有依赖项都可以通过这种方式引入项目。某些依赖项定义的目标名称与项目或其他依赖项中的其他目标冲突。由 add_executable()
和 add_library()
创建的具体可执行文件和库目标是全局的,因此每个目标在整个构建中都必须是唯一的。如果依赖项会添加冲突的目标名称,则无法使用此方法直接将其引入构建中。
FetchContent
和 find_package()
集成¶
在 3.24 版本中添加。
某些依赖项支持通过 find_package()
或 FetchContent
添加。此类依赖项必须确保在已安装和从源代码构建的情况下都定义相同的命名空间目标。然后,使用项目链接到这些命名空间目标,并且可以透明地处理这两种情况,只要项目不使用任何其他两种方法都未提供的内容。
项目可以使用 FIND_PACKAGE_ARGS
选项向 FetchContent_Declare()
指示它乐于接受通过任一方法提供的依赖项。这允许 FetchContent_MakeAvailable()
首先尝试通过调用 find_package()
来满足依赖项,使用 FIND_PACKAGE_ARGS
关键字之后的任何参数(如果有)。如果找不到依赖项,则如前所述从源代码构建它。
include(FetchContent)
FetchContent_Declare(
googletest
GIT_REPOSITORY https://github.com/google/googletest.git
GIT_TAG 703bd9caab50b139428cea1aaff9974ebee5742e # release-1.10.0
FIND_PACKAGE_ARGS NAMES GTest
)
FetchContent_MakeAvailable(googletest)
add_executable(ThingUnitTest thing_ut.cpp)
target_link_libraries(ThingUnitTest GTest::gtest_main)
上面的示例首先调用 find_package(googletest NAMES GTest)
。CMake 提供了一个 FindGTest
模块,因此如果它找到在某处安装的 GTest 包,它将使其可用,并且依赖项将不会从源代码构建。如果找不到 GTest 包,则将从源代码构建它。在任何一种情况下,都应定义 GTest::gtest_main
目标,因此我们将单元测试可执行文件链接到该目标。
也可以通过 FETCHCONTENT_TRY_FIND_PACKAGE_MODE
变量进行高级控制。可以将其设置为 NEVER
以禁用所有重定向到 find_package()
。可以将其设置为 ALWAYS
以尝试 find_package()
,即使未指定 FIND_PACKAGE_ARGS
(应谨慎使用)。
项目也可能决定必须从源代码构建特定的依赖项。如果需要已修补或未发布的依赖项版本,或者为了满足某些策略(要求所有依赖项都从源代码构建),则可能需要这样做。项目可以通过将 OVERRIDE_FIND_PACKAGE
关键字添加到 FetchContent_Declare()
来强制执行此操作。然后,对该依赖项的 find_package()
调用将被重定向到 FetchContent_MakeAvailable()
。
include(FetchContent)
FetchContent_Declare(
Catch2
URL https://intranet.mycomp.com/vendored/Catch2_2.13.4_patched.tgz
URL_HASH MD5=abc123...
OVERRIDE_FIND_PACKAGE
)
# The following is automatically redirected to FetchContent_MakeAvailable(Catch2)
find_package(Catch2)
有关更高级的用例,请参阅 CMAKE_FIND_PACKAGE_REDIRECTS_DIR
变量。
依赖项提供程序¶
在 3.24 版本中添加。
前面的章节讨论了项目可以用来指定其依赖项的技术。理想情况下,项目实际上不应该关心依赖项来自哪里,只要它提供了项目期望的内容(通常只是一些导入的目标)。项目说明了它需要什么,并且在没有任何其他详细信息的情况下,也可以指定从哪里获取它,以便仍然可以开箱即用地构建它。
另一方面,开发人员可能对控制如何向项目提供依赖项更感兴趣。您可能想使用您自己构建的特定版本的包。您可能想使用第三方包管理器。您可能想出于安全或性能原因将某些请求重定向到您控制的系统上的不同 URL。CMake 通过 依赖项提供程序 支持这些类型的场景。
可以设置依赖项提供程序来拦截 find_package()
和 FetchContent_MakeAvailable()
调用。提供程序有机会在回退到内置实现(如果提供程序未满足请求)之前满足此类请求。
只能设置一个依赖项提供程序,并且只能在 CMake 运行非常早期的特定点设置它。CMAKE_PROJECT_TOP_LEVEL_INCLUDES
变量列出了在处理第一个 project()
调用(且仅该调用)时将读取的 CMake 文件。这是唯一可以设置依赖项提供程序的时间。在整个项目中,最多应使用一个提供程序。
在某些情况下,用户无需了解依赖提供程序是如何设置的细节。第三方可以提供一个文件,该文件可以添加到 CMAKE_PROJECT_TOP_LEVEL_INCLUDES
中,这将代表用户设置依赖提供程序。这是包管理器推荐的方法。开发者可以像这样使用这样的文件
cmake -DCMAKE_PROJECT_TOP_LEVEL_INCLUDES=/path/to/package_manager/setup.cmake ...
有关如何实现您自己的自定义依赖提供程序的详细信息,请参阅 cmake_language(SET_DEPENDENCY_PROVIDER)
命令。