cmake_language¶

在 3.18 版本中新增。

对 CMake 命令执行元操作。

概要¶

cmake_language(CALL <command> [<arg>...])
cmake_language(EVAL CODE <code>...)
cmake_language(DEFER <options>... CALL <command> [<arg>...])
cmake_language(SET_DEPENDENCY_PROVIDER <command> SUPPORTED_METHODS <methods>...)
cmake_language(GET_MESSAGE_LOG_LEVEL <out-var>)
cmake_language(EXIT <exit-code>)
cmake_language(TRACE <boolean> ...)

简介¶

此命令用于对内置 CMake 命令或通过 macro() 或 function() 命令创建的自定义命令执行元操作。

cmake_language 不会引入新的变量或策略作用域。

调用命令¶

cmake_language(CALL <command> [<arg>...])¶

使用给定的参数（如果有）调用指定的 <command>。例如，代码

set(message_command "message")
cmake_language(CALL ${message_command} STATUS "Hello World!")

等价于

message(STATUS "Hello World!")

注意

为确保代码一致性，以下命令不允许使用：

if / elseif / else / endif
block / endblock
while / endwhile
foreach / endforeach
function / endfunction
macro / endmacro

评估代码¶

cmake_language(EVAL CODE <code>...)¶

将 <code>... 作为 CMake 代码进行评估。

例如，以下代码：

set(A TRUE)
set(B TRUE)
set(C TRUE)
set(condition "(A AND B) OR C")

cmake_language(EVAL CODE "
  if (${condition})
    message(STATUS TRUE)
  else()
    message(STATUS FALSE)
  endif()"
)

等价于

set(A TRUE)
set(B TRUE)
set(C TRUE)
set(condition "(A AND B) OR C")

file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/eval.cmake "
  if (${condition})
    message(STATUS TRUE)
  else()
    message(STATUS FALSE)
  endif()"
)

include(${CMAKE_CURRENT_BINARY_DIR}/eval.cmake)

延迟调用¶

3.19 版本新增。

cmake_language(DEFER <options>... CALL <command> [<arg>...])¶

安排在稍后时间调用指定的 <command> 并传入给定参数（如果有）。默认情况下，延迟调用就像写在当前目录的 CMakeLists.txt 文件末尾一样执行，不同之处在于即使在 return() 调用之后它们也会运行。参数中的变量引用在延迟调用执行时进行评估。

选项包括

DIRECTORY <dir>

安排在指定目录的末尾而不是当前目录调用。 <dir> 可以引用源目录或其对应的二进制目录。相对路径被视为相对于当前源目录。

给定的目录必须是 CMake 已知的，即顶层目录或通过 add_subdirectory() 添加的目录。此外，给定的目录必须尚未完成处理。这意味着它可以是当前目录或其祖先目录之一。

ID <id>

指定延迟调用的标识符。<id> 不能留空，且不能以大写字母 A-Z 开头。<id> 仅在由之前使用 ID_VAR 获取 ID 的调用自动生成时，才能以下划线 (_) 开头。

ID_VAR <var>

指定一个用于存储延迟调用标识符的变量。如果未提供 ID <id>，则会生成一个新的标识符，该生成的 ID 将以下划线 (_) 开头。

可以获取当前计划的延迟调用列表

cmake_language(DEFER [DIRECTORY <dir>] GET_CALL_IDS <var>)

这会将延迟调用 ID 的分号分隔列表存储在 <var> 中。这些 ID 是针对调用所延迟到的目录作用域（即执行它们的地方）的，这可能与创建它们的作用域不同。DIRECTORY 选项可用于指定要获取调用 ID 的作用域。如果未提供该选项，则返回当前目录作用域的调用 ID。

可以根据 ID 获取特定调用的详细信息

cmake_language(DEFER [DIRECTORY <dir>] GET_CALL <id> <var>)

这会将一个分号分隔列表存储在 <var> 中，其中第一个元素是要调用的命令名称，其余元素是其未评估的参数（包含的任何 ; 字符均按字面意思包含，无法与多个参数区分）。如果使用相同的 ID 调度了多个调用，则获取第一个调用。如果指定 DIRECTORY 作用域内（如果未提供 DIRECTORY 选项，则为当前目录作用域）没有使用给定 ID 调度的调用，则变量中存储空字符串。

可以通过 ID 取消延迟调用

cmake_language(DEFER [DIRECTORY <dir>] CANCEL_CALL <id>...)

这将取消指定 DIRECTORY 作用域（如果未提供 DIRECTORY 选项，则为当前目录作用域）内匹配任何给定 ID 的所有延迟调用。未知的 ID 会被静默忽略。

延迟调用示例¶

例如，以下代码：

cmake_language(DEFER CALL message "${deferred_message}")
cmake_language(DEFER ID_VAR id CALL message "Canceled Message")
cmake_language(DEFER CANCEL_CALL ${id})
message("Immediate Message")
set(deferred_message "Deferred Message")

输出

Immediate Message
Deferred Message

Canceled Message 从未被打印，因为它的命令被取消了。deferred_message 变量引用直到调用点才会被评估，因此可以在调度延迟调用后进行设置。

为了在调度延迟调用时立即评估变量引用，请使用 cmake_language(EVAL) 包装它。但是，请注意参数将在延迟调用中重新评估，不过可以通过使用括号参数来避免这种情况。例如

set(deferred_message "Deferred Message 1")
set(re_evaluated [[${deferred_message}]])
cmake_language(EVAL CODE "
  cmake_language(DEFER CALL message [[${deferred_message}]])
  cmake_language(DEFER CALL message \"${re_evaluated}\")
")
message("Immediate Message")
set(deferred_message "Deferred Message 2")

也输出

Immediate Message
Deferred Message 1
Deferred Message 2

依赖提供程序¶

在 3.24 版本中添加。

注意

有关此功能的高级介绍，请参阅使用依赖项指南。

cmake_language(SET_DEPENDENCY_PROVIDER <command> SUPPORTED_METHODS <methods>...)¶

当调用 find_package() 或 FetchContent_MakeAvailable() 时，调用可能会转发给依赖提供程序，提供程序随后有机会满足该请求。如果请求是设置提供程序时指定的 <methods> 之一，CMake 将调用提供程序的 <command> 并传入一组特定于方法参数。如果提供程序未满足请求，或者提供程序不支持该请求的方法，亦或未设置提供程序，则使用内置的 find_package() 或 FetchContent_MakeAvailable() 实现以常规方式满足请求。

设置提供程序时，可以为 <methods> 指定以下一个或多个值：

FIND_PACKAGE: 提供程序命令接受 find_package() 请求。
FETCHCONTENT_MAKEAVAILABLE_SERIAL: 提供程序命令接受 FetchContent_MakeAvailable() 请求。它期望每个依赖项一次一个地输入到提供程序命令中，而不是一次性处理整个列表。

在任何时间点只能设置一个提供程序。如果在调用 cmake_language(SET_DEPENDENCY_PROVIDER) 时已经设置了提供程序，则新的提供程序将替换之前设置的提供程序。在调用 cmake_language(SET_DEPENDENCY_PROVIDER) 时，指定的 <command> 必须已经存在。作为一种特殊情况，为 <command> 提供空字符串且不指定 <methods> 将丢弃任何先前设置的提供程序。

依赖提供程序只能在处理 CMAKE_PROJECT_TOP_LEVEL_INCLUDES 变量指定的文件之一时设置。因此，依赖提供程序只能作为第一次调用 project() 的一部分进行设置。在此上下文之外调用 cmake_language(SET_DEPENDENCY_PROVIDER) 将导致错误。

Added in version 3.30: 如果依赖提供程序也希望在全项目范围的 try_compile() 调用中启用，则可以设置 PROPAGATE_TOP_LEVEL_INCLUDES_TO_TRY_COMPILE 全局属性。

注意

依赖提供程序的选择应始终由用户控制。为方便起见，项目可以选择提供一个文件，用户可以在其 CMAKE_PROJECT_TOP_LEVEL_INCLUDES 变量中列出该文件，但使用此类文件应始终由用户自行决定。

提供程序命令¶

提供程序定义单个 <command> 来接收请求。命令名称应特定于该提供程序，而不是其他提供程序也可能使用的过于通用的名称。这使得用户可以在自己的自定义提供程序中组合不同的提供程序。建议的形式是 xxx_provide_dependency()，其中 xxx 是提供程序特定部分（例如 vcpkg_provide_dependency()、conan_provide_dependency()、ourcompany_provide_dependency() 等）。

xxx_provide_dependency(<method> [<method-specific-args>...])

由于某些方法要求在调用作用域中设置某些变量，提供程序命令通常应实现为宏而不是函数。这确保它不会引入新的变量作用域。

CMake 传递给依赖提供程序的参数取决于请求类型。第一个参数始终是方法，并且它将仅是设置提供程序时指定的 <methods> 之一。

FIND_PACKAGE

<method-specific-args> 将是传递给请求依赖项的 find_package() 调用的所有内容。因此，这些 <method-specific-args> 中的第一个始终是依赖项的名称。在此方法中，依赖项名称区分大小写，因为 find_package() 处理它们也区分大小写。

如果提供程序命令满足了请求，它必须设置 find_package() 期望设置的同一变量。对于名为 depName 的依赖项，如果提供程序满足了请求，则必须将 depName_FOUND 设置为 true。如果提供程序返回时未设置此变量，CMake 将假设请求未满足，并回退到内置实现。

如果提供程序需要调用内置的 find_package() 实现作为其处理的一部分，它可以通过将 BYPASS_PROVIDER 关键字作为参数之一包含进来来实现。

FETCHCONTENT_MAKEAVAILABLE_SERIAL

<method-specific-args> 将是传递给与请求的依赖项对应的 FetchContent_Declare() 调用的所有内容，但以下例外情况除外：

如果 SOURCE_DIR 或 BINARY_DIR 不是原始声明参数的一部分，它们将添加默认值。
如果 FETCHCONTENT_TRY_FIND_PACKAGE_MODE 设置为 NEVER，则任何 FIND_PACKAGE_ARGS 都将被省略。
OVERRIDE_FIND_PACKAGE 关键字始终被省略。

<method-specific-args> 中的第一个始终是依赖项的名称。在此方法中，依赖项名称不区分大小写，因为 FetchContent 也处理它们不区分大小写。

如果提供程序满足了请求，它应该调用 FetchContent_SetPopulated()，并将依赖项名称作为第一个参数传递。仅当提供程序以与内置 FetchContent_MakeAvailable() 命令完全相同的方式提供依赖项的源目录和构建目录时，才应为该命令提供 SOURCE_DIR 和 BINARY_DIR 参数。

如果提供程序返回时未调用 FetchContent_SetPopulated() 来处理已命名的依赖项，CMake 将假设请求未满足，并回退到内置实现。

请注意，空参数对于此方法可能很重要（例如 GIT_SUBMODULES 关键字后的空字符串）。因此，如果将这些参数转发给另一个命令，必须格外小心，以避免此类参数被静默丢弃。

如果设置了 FETCHCONTENT_SOURCE_DIR_<uppercaseDepName>，则依赖提供程序将永远不会看到此方法的 <depName> 依赖项请求。当用户设置此类变量时，他们明确覆盖了该依赖项的获取来源，并承担其覆盖版本满足该依赖项的任何要求，并与项目中其他使用它的内容兼容的责任。根据 FETCHCONTENT_TRY_FIND_PACKAGE_MODE 的值，以及是否向 FetchContent_Declare() 提供了 OVERRIDE_FIND_PACKAGE 选项，设置 FETCHCONTENT_SOURCE_DIR_<uppercaseDepName> 可能也会阻止依赖提供程序看到 find_package(depName) 调用的请求。

提供程序示例¶

第一个示例仅拦截 find_package() 调用。如果该工具知道该依赖项，则提供程序命令会运行一个外部工具，将相关工件复制到特定于提供程序的目录中。然后它依赖内置实现来查找这些工件。FetchContent_MakeAvailable() 调用不会经过提供程序。

mycomp_provider.cmake¶

# Always ensure we have the policy settings this provider expects
cmake_minimum_required(VERSION 3.24)

set(MYCOMP_PROVIDER_INSTALL_DIR ${CMAKE_BINARY_DIR}/mycomp_packages
  CACHE PATH "The directory this provider installs packages to"
)
# Tell the built-in implementation to look in our area first, unless
# the find_package() call uses NO_..._PATH options to exclude it
list(APPEND CMAKE_MODULE_PATH ${MYCOMP_PROVIDER_INSTALL_DIR}/cmake)
list(APPEND CMAKE_PREFIX_PATH ${MYCOMP_PROVIDER_INSTALL_DIR})

macro(mycomp_provide_dependency method package_name)
  execute_process(
    COMMAND some_tool ${package_name} --installdir ${MYCOMP_PROVIDER_INSTALL_DIR}
    COMMAND_ERROR_IS_FATAL ANY
  )
endmacro()

cmake_language(
  SET_DEPENDENCY_PROVIDER mycomp_provide_dependency
  SUPPORTED_METHODS FIND_PACKAGE
)

用户通常会这样使用上述文件

cmake -DCMAKE_PROJECT_TOP_LEVEL_INCLUDES=/path/to/mycomp_provider.cmake ...

下一个示例演示了一个接受两种方法但只处理一个特定依赖项的提供程序。它强制使用 FetchContent 提供 Google Test，但将所有其他依赖项留给 CMake 的内置实现来满足。它接受几个不同的名称，这演示了解决那些硬编码不寻常或不良方式来将特定依赖项添加到构建中的项目的一种方法。该示例还演示了如何使用 list() 命令来保留可能被调用 FetchContent_MakeAvailable() 覆盖的变量。

mycomp_provider.cmake¶

cmake_minimum_required(VERSION 3.24)

# Because we declare this very early, it will take precedence over any
# details the project might declare later for the same thing
include(FetchContent)
FetchContent_Declare(
  googletest
  GIT_REPOSITORY https://github.com/google/googletest.git
  GIT_TAG        e2239ee6043f73722e7aa812a459f54a28552929 # release-1.11.0
)

# Both FIND_PACKAGE and FETCHCONTENT_MAKEAVAILABLE_SERIAL methods provide
# the package or dependency name as the first method-specific argument.
macro(mycomp_provide_dependency method dep_name)
  if("${dep_name}" MATCHES "^(gtest|googletest)$")
    # Save our current command arguments in case we are called recursively
    list(APPEND mycomp_provider_args ${method} ${dep_name})

    # This will forward to the built-in FetchContent implementation,
    # which detects a recursive call for the same thing and avoids calling
    # the provider again if dep_name is the same as the current call.
    FetchContent_MakeAvailable(googletest)

    # Restore our command arguments
    list(POP_BACK mycomp_provider_args dep_name method)

    # Tell the caller we fulfilled the request
    if("${method}" STREQUAL "FIND_PACKAGE")
      # We need to set this if we got here from a find_package() call
      # since we used a different method to fulfill the request.
      # This example assumes projects only use the gtest targets,
      # not any of the variables the FindGTest module may define.
      set(${dep_name}_FOUND TRUE)
    elseif(NOT "${dep_name}" STREQUAL "googletest")
      # We used the same method, but were given a different name to the
      # one we populated with. Tell the caller about the name it used.
      FetchContent_SetPopulated(${dep_name}
        SOURCE_DIR "${googletest_SOURCE_DIR}"
        BINARY_DIR "${googletest_BINARY_DIR}"
      )
    endif()
  endif()
endmacro()

cmake_language(
  SET_DEPENDENCY_PROVIDER mycomp_provide_dependency
  SUPPORTED_METHODS
    FIND_PACKAGE
    FETCHCONTENT_MAKEAVAILABLE_SERIAL
)

最后一个示例演示了如何修改 find_package() 调用的参数。它强制所有此类调用都具有 QUIET 关键字。它使用 BYPASS_PROVIDER 关键字来防止为同一个依赖项递归调用提供程序命令。

mycomp_provider.cmake¶

cmake_minimum_required(VERSION 3.24)

macro(mycomp_provide_dependency method)
  find_package(${ARGN} BYPASS_PROVIDER QUIET)
endmacro()

cmake_language(
  SET_DEPENDENCY_PROVIDER mycomp_provide_dependency
  SUPPORTED_METHODS FIND_PACKAGE
)

获取当前消息日志级别¶

在 3.25 版本中新增。

cmake_language(GET_MESSAGE_LOG_LEVEL <output_variable>)¶

将当前的 message() 日志级别写入给定的 <output_variable>。

有关可能的日志级别，请参阅 message()。

当前消息日志级别可以使用 cmake(1) 程序的 --log-level 命令行选项设置，也可以使用 CMAKE_MESSAGE_LOG_LEVEL 变量设置。

如果同时设置了命令行选项和变量，则命令行选项优先。如果两者均未设置，则返回默认日志级别。

终止脚本¶

在版本 3.29 中添加。

cmake_language(EXIT <exit-code>)¶

终止当前的 cmake -P 脚本并以 <exit-code> 退出。

此命令仅在脚本模式下有效。如果在该上下文之外使用，将导致致命错误。

<exit-code> 应为非负数。如果 <exit-code> 为负数，则行为未定义（例如，在 Windows 上错误代码 -1 变为 0xffffffff，在 Linux 上变为 255）。底层 shell 或平台可能不支持超过 255 的退出代码，某些 shell 可能会特殊解释大于 125 的值。因此，建议仅指定 0 到 125 范围内的 <exit-code>。

跟踪控制¶

版本 4.2 中添加。

cmake_language(TRACE ON [EXPAND])¶

cmake_language(TRACE OFF)¶

TRACE 子命令控制当前进程内执行的 CMake 命令和宏的运行时跟踪。启用后，跟踪输出的格式与 CMake 使用 cmake --trace 或 cmake --trace-expand 命令行选项启动时的格式相同。

跟踪作用域是可以嵌套的。多个 TRACE ON 调用可以同时处于活动状态，并且每个 TRACE OFF 都会停用一个嵌套级别。

如果 CMake 使用 cmake --trace 或 cmake --trace-expand 运行，则无论 cmake_language(TRACE OFF) 调用如何，这些选项都会覆盖并强制全局跟踪。在这种情况下，该命令仍可被调用，但对跟踪状态没有影响。

cmake_language¶

概要¶

简介¶

调用命令¶

评估代码¶

延迟调用¶

延迟调用示例¶

依赖提供程序¶

提供程序命令¶

提供程序示例¶

获取当前消息日志级别¶

终止脚本¶

跟踪控制¶

目录

上一主题

下一主题

本页