cmake_language¶

在版本 3.18 中添加。

在 CMake 命令上调用元操作。

概要¶

cmake_language(CALL <command> [<arg>...])
cmake_language(EVAL CODE <code>...)
cmake_language(DEFER <options>... CALL <command> [<arg>...])
cmake_language(SET_DEPENDENCY_PROVIDER <command> SUPPORTED_METHODS <methods>...)
cmake_language(GET_MESSAGE_LOG_LEVEL <out-var>)
cmake_language(EXIT <exit-code>)

简介¶

此命令将在内置 CMake 命令或通过 macro() 或 function() 命令创建的命令上调用元操作。

cmake_language 不会引入新的变量或策略范围。

调用命令¶

cmake_language(CALL <command> [<arg>...])¶

使用给定的参数（如果有）调用名为 <command> 的命令。例如，代码

set(message_command "message")
cmake_language(CALL ${message_command} STATUS "Hello World!")

等效于

message(STATUS "Hello World!")

注意

为了确保代码的一致性，以下命令不允许使用

if / elseif / else / endif
block / endblock
while / endwhile
foreach / endforeach
function / endfunction
macro / endmacro

评估代码¶

cmake_language(EVAL CODE <code>...)¶

将 <code>... 评估为 CMake 代码。

例如，代码

set(A TRUE)
set(B TRUE)
set(C TRUE)
set(condition "(A AND B) OR C")

cmake_language(EVAL CODE "
  if (${condition})
    message(STATUS TRUE)
  else()
    message(STATUS FALSE)
  endif()"
)

等效于

set(A TRUE)
set(B TRUE)
set(C TRUE)
set(condition "(A AND B) OR C")

file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/eval.cmake "
  if (${condition})
    message(STATUS TRUE)
  else()
    message(STATUS FALSE)
  endif()"
)

include(${CMAKE_CURRENT_BINARY_DIR}/eval.cmake)

推迟调用¶

在版本 3.19 中添加。

cmake_language(DEFER <options>... CALL <command> [<arg>...])¶

安排在稍后时间调用名为 <command> 的命令，并使用给定的参数（如果有）。默认情况下，延迟调用会像在当前目录的 CMakeLists.txt 文件末尾编写一样执行，但即使在 return() 调用之后也会运行。参数中的变量引用会在延迟调用执行时进行评估。

选项为

DIRECTORY <dir>

安排在给定目录的末尾而不是当前目录进行调用。<dir> 可以引用源目录或其对应的二进制目录。相对路径被视为相对于当前源目录。

给定目录必须是 CMake 已知的，是顶级目录，或者是通过 add_subdirectory() 添加的目录。此外，给定目录不能在处理完之前被完成。这意味着它可以是当前目录或其祖先之一。

ID <id>

为延迟调用指定一个标识。<id> 不能为空，也不能以大写字母 A-Z 开头。<id> 只能在它由先前使用 ID_VAR 获取 id 的调用自动生成的情况下以下划线 (_) 开头。

ID_VAR <var>

指定一个变量，用于存储延迟调用的标识。如果没有给出 ID <id>，将生成一个新的标识，并且生成的 id 将以下划线 (_) 开头。

当前安排的延迟调用列表可以通过以下方式检索

cmake_language(DEFER [DIRECTORY <dir>] GET_CALL_IDS <var>)

这将存储在 <var> 中，是一个以分号分隔的列表，其中包含延迟调用 id。这些 id 用于调用被延迟到的目录范围（即它们将要执行的地方），这可能与它们创建的范围不同。DIRECTORY 选项可用于指定用于检索调用 id 的范围。如果没有给出该选项，将返回当前目录范围的调用 id。

特定调用的详细信息可以通过其 id 检索

cmake_language(DEFER [DIRECTORY <dir>] GET_CALL <id> <var>)

这将存储在 <var> 中，是一个以分号分隔的列表，其中第一个元素是将要调用的命令的名称，其余元素是其未评估的参数（任何包含的 ; 字符将按字面意思包含，无法与多个参数区分）。如果多个调用使用相同的 id 进行安排，则检索第一个。如果在指定的 DIRECTORY 范围内（如果没有给出 DIRECTORY 选项，则为当前目录范围）没有使用给定 id 安排调用，则此方法会在变量中存储一个空字符串。

延迟调用可以通过其 id 取消

cmake_language(DEFER [DIRECTORY <dir>] CANCEL_CALL <id>...)

这将取消在指定的 DIRECTORY 范围内（如果没有给出 DIRECTORY 选项，则为当前目录范围）匹配任何给定 id 的所有延迟调用。未知 id 会被静默忽略。

延迟调用示例¶

例如，代码

cmake_language(DEFER CALL message "${deferred_message}")
cmake_language(DEFER ID_VAR id CALL message "Canceled Message")
cmake_language(DEFER CANCEL_CALL ${id})
message("Immediate Message")
set(deferred_message "Deferred Message")

打印

Immediate Message
Deferred Message

Canceled Message 从未打印，因为其命令被取消了。deferred_message 变量引用直到调用站点才会进行评估，因此它可以在延迟调用安排之后设置。

为了在安排延迟调用时立即评估变量引用，请使用 cmake_language(EVAL) 将其包装起来。但是，请注意，参数将在延迟调用中重新评估，尽管可以使用括号参数来避免这种情况。例如

set(deferred_message "Deferred Message 1")
set(re_evaluated [[${deferred_message}]])
cmake_language(EVAL CODE "
  cmake_language(DEFER CALL message [[${deferred_message}]])
  cmake_language(DEFER CALL message \"${re_evaluated}\")
")
message("Immediate Message")
set(deferred_message "Deferred Message 2")

也会打印

Immediate Message
Deferred Message 1
Deferred Message 2

依赖项提供者¶

在版本 3.24 中添加。

注意

有关此功能的更高级介绍，请参阅使用依赖项指南。

cmake_language(SET_DEPENDENCY_PROVIDER <command> SUPPORTED_METHODS <methods>...)¶

当调用 find_package() 或 FetchContent_MakeAvailable() 时，该调用可能会转发到一个依赖项提供者，然后该提供者有机会完成请求。如果请求是针对设置提供者时指定的 <methods> 之一，CMake 将使用一组特定于方法的参数调用提供者的 <command>。如果提供者没有完成请求，或者提供者不支持请求的方法，或者没有设置提供者，则使用内置的 find_package() 或 FetchContent_MakeAvailable() 实现来以通常的方式完成请求。

在设置提供者时，可以为 <methods> 指定以下值之一或多个

FIND_PACKAGE: 提供者命令接受 find_package() 请求。
FETCHCONTENT_MAKEAVAILABLE_SERIAL: 提供者命令接受 FetchContent_MakeAvailable() 请求。它期望每个依赖项一次一个地被提供给提供者命令，而不是一次全部提供整个列表。

在任何时候只能设置一个提供者。如果在调用 cmake_language(SET_DEPENDENCY_PROVIDER) 时已经设置了提供者，则新的提供者将替换先前设置的提供者。指定的 <command> 必须在调用 cmake_language(SET_DEPENDENCY_PROVIDER) 时已经存在。作为一种特殊情况，为 <command> 提供空字符串，并且没有 <methods> 将丢弃任何先前设置的提供者。

依赖提供者只能在处理由 CMAKE_PROJECT_TOP_LEVEL_INCLUDES 变量指定的其中一个文件时设置。因此，依赖提供者只能作为对 project() 的第一次调用的一部分进行设置。在该上下文中调用 cmake_language(SET_DEPENDENCY_PROVIDER) 将导致错误。

在版本 3.30 中添加：如果依赖提供者也希望在对 try_compile() 的整个项目调用中启用，则可以设置 PROPAGATE_TOP_LEVEL_INCLUDES_TO_TRY_COMPILE 全局属性。

注意

依赖提供者的选择应该始终在用户的控制之下。为了方便起见，项目可以选择提供一个文件，用户可以在其 CMAKE_PROJECT_TOP_LEVEL_INCLUDES 变量中列出该文件，但使用此类文件应该始终是用户的选择。

提供者命令¶

提供者定义一个唯一的 <command> 来接受请求。命令的名称应该特定于该提供者，而不是其他提供者也可能使用的过于通用的名称。这使用户能够在其自己的自定义提供者中组合不同的提供者。建议的形式是 xxx_provide_dependency()，其中 xxx 是特定于提供者的部分（例如 vcpkg_provide_dependency()、conan_provide_dependency()、ourcompany_provide_dependency() 等）。

xxx_provide_dependency(<method> [<method-specific-args>...])

由于某些方法期望在调用范围内设置某些变量，因此提供者命令通常应实现为宏，而不是函数。这确保它不会引入新的变量范围。

CMake 传递给依赖提供者的参数取决于请求的类型。第一个参数始终是方法，它只可能是设置提供者时指定的 <methods> 之一。

FIND_PACKAGE

该 <method-specific-args> 将是传递给请求依赖项的 find_package() 调用的所有内容。因此，这些 <method-specific-args> 中的第一个将始终是依赖项的名称。依赖项名称对于此方法区分大小写，因为 find_package() 也区分大小写。

如果提供者命令满足请求，它必须设置与 find_package() 预期设置的相同变量。对于名为 depName 的依赖项，提供者必须将 depName_FOUND 设置为 true，如果它满足了请求。如果提供者在没有设置此变量的情况下返回，CMake 将假设请求未满足，并将回退到内置实现。

如果提供者需要调用内置的 find_package() 实现作为其处理的一部分，它可以通过将 BYPASS_PROVIDER 关键字作为参数之一来进行。

FETCHCONTENT_MAKEAVAILABLE_SERIAL

该 <method-specific-args> 将是传递给对应于所请求依赖项的 FetchContent_Declare() 调用的所有内容，但以下情况除外

如果 SOURCE_DIR 或 BINARY_DIR 不是原始声明参数的一部分，它们将以其默认值添加。
如果 FETCHCONTENT_TRY_FIND_PACKAGE_MODE 设置为 NEVER，任何 FIND_PACKAGE_ARGS 都将被省略。
该 OVERRIDE_FIND_PACKAGE 关键字始终被省略。

这些 <method-specific-args> 中的第一个将始终是依赖项的名称。依赖项名称对于此方法不区分大小写，因为 FetchContent 也不区分大小写。

如果提供者满足请求，它应该调用 FetchContent_SetPopulated()，将依赖项的名称作为第一个参数传递。该命令的 SOURCE_DIR 和 BINARY_DIR 参数应该只在提供者以与内置的 FetchContent_MakeAvailable() 命令完全相同的方式提供依赖项的源目录和构建目录时才给出。

如果提供者在没有为命名依赖项调用 FetchContent_SetPopulated() 的情况下返回，CMake 将假设请求未满足，并将回退到内置实现。

请注意，对于此方法，空参数可能具有重要意义（例如，在 GIT_SUBMODULES 关键字后面的空字符串）。因此，如果将这些参数转发到另一个命令，则必须格外小心，避免这些参数被静默删除。

如果设置了 FETCHCONTENT_SOURCE_DIR_<uppercaseDepName>，则依赖项提供者将永远不会看到针对此方法的 <depName> 依赖项的请求。当用户设置此类变量时，他们明确地覆盖了从何处获取该依赖项，并承担了他们的覆盖版本满足该依赖项的任何要求并且与项目中使用它的任何其他内容兼容的责任。根据 FETCHCONTENT_TRY_FIND_PACKAGE_MODE 的值以及是否向 FetchContent_Declare() 提供了 OVERRIDE_FIND_PACKAGE 选项，设置 FETCHCONTENT_SOURCE_DIR_<uppercaseDepName> 也可能阻止依赖项提供者看到对 find_package(depName) 调用的请求。

提供者示例¶

第一个示例只拦截 find_package() 调用。提供者命令运行一个外部工具，如果该工具知道依赖项，则将相关工件复制到特定于提供者的目录中。然后，它依赖于内置实现来查找这些工件。 FetchContent_MakeAvailable() 调用不会通过提供者进行。

mycomp_provider.cmake¶

# Always ensure we have the policy settings this provider expects
cmake_minimum_required(VERSION 3.24)

set(MYCOMP_PROVIDER_INSTALL_DIR ${CMAKE_BINARY_DIR}/mycomp_packages
  CACHE PATH "The directory this provider installs packages to"
)
# Tell the built-in implementation to look in our area first, unless
# the find_package() call uses NO_..._PATH options to exclude it
list(APPEND CMAKE_MODULE_PATH ${MYCOMP_PROVIDER_INSTALL_DIR}/cmake)
list(APPEND CMAKE_PREFIX_PATH ${MYCOMP_PROVIDER_INSTALL_DIR})

macro(mycomp_provide_dependency method package_name)
  execute_process(
    COMMAND some_tool ${package_name} --installdir ${MYCOMP_PROVIDER_INSTALL_DIR}
    COMMAND_ERROR_IS_FATAL ANY
  )
endmacro()

cmake_language(
  SET_DEPENDENCY_PROVIDER mycomp_provide_dependency
  SUPPORTED_METHODS FIND_PACKAGE
)

然后，用户通常会像这样使用上面的文件

cmake -DCMAKE_PROJECT_TOP_LEVEL_INCLUDES=/path/to/mycomp_provider.cmake ...

下一个示例演示了一个接受两种方法但只处理一个特定依赖项的提供者。它强制使用 FetchContent 提供 Google Test，但将所有其他依赖项留给 CMake 的内置实现来满足。它接受几个不同的名称，这展示了一种绕过将此特定依赖项以非正常或不可取的方式硬编码到构建中的项目的方法。该示例还演示了如何使用 list() 命令来保留可能被对 FetchContent_MakeAvailable() 的调用覆盖的变量。

mycomp_provider.cmake¶

cmake_minimum_required(VERSION 3.24)

# Because we declare this very early, it will take precedence over any
# details the project might declare later for the same thing
include(FetchContent)
FetchContent_Declare(
  googletest
  GIT_REPOSITORY https://github.com/google/googletest.git
  GIT_TAG        e2239ee6043f73722e7aa812a459f54a28552929 # release-1.11.0
)

# Both FIND_PACKAGE and FETCHCONTENT_MAKEAVAILABLE_SERIAL methods provide
# the package or dependency name as the first method-specific argument.
macro(mycomp_provide_dependency method dep_name)
  if("${dep_name}" MATCHES "^(gtest|googletest)$")
    # Save our current command arguments in case we are called recursively
    list(APPEND mycomp_provider_args ${method} ${dep_name})

    # This will forward to the built-in FetchContent implementation,
    # which detects a recursive call for the same thing and avoids calling
    # the provider again if dep_name is the same as the current call.
    FetchContent_MakeAvailable(googletest)

    # Restore our command arguments
    list(POP_BACK mycomp_provider_args dep_name method)

    # Tell the caller we fulfilled the request
    if("${method}" STREQUAL "FIND_PACKAGE")
      # We need to set this if we got here from a find_package() call
      # since we used a different method to fulfill the request.
      # This example assumes projects only use the gtest targets,
      # not any of the variables the FindGTest module may define.
      set(${dep_name}_FOUND TRUE)
    elseif(NOT "${dep_name}" STREQUAL "googletest")
      # We used the same method, but were given a different name to the
      # one we populated with. Tell the caller about the name it used.
      FetchContent_SetPopulated(${dep_name}
        SOURCE_DIR "${googletest_SOURCE_DIR}"
        BINARY_DIR "${googletest_BINARY_DIR}"
      )
    endif()
  endif()
endmacro()

cmake_language(
  SET_DEPENDENCY_PROVIDER mycomp_provide_dependency
  SUPPORTED_METHODS
    FIND_PACKAGE
    FETCHCONTENT_MAKEAVAILABLE_SERIAL
)

最后一个示例演示了如何修改对 find_package() 调用的参数。它强制所有此类调用都具有 QUIET 关键字。它使用 BYPASS_PROVIDER 关键字来防止对同一个依赖项递归调用提供者命令。

mycomp_provider.cmake¶

cmake_minimum_required(VERSION 3.24)

macro(mycomp_provide_dependency method)
  find_package(${ARGN} BYPASS_PROVIDER QUIET)
endmacro()

cmake_language(
  SET_DEPENDENCY_PROVIDER mycomp_provide_dependency
  SUPPORTED_METHODS FIND_PACKAGE
)

获取当前消息日志级别¶

在 3.25 版本中添加。

cmake_language(GET_MESSAGE_LOG_LEVEL <output_variable>)¶

将当前 message() 日志级别写入给定的 <output_variable>。

有关可能的日志级别，请参阅 message()。

可以使用 --log-level 命令行选项（适用于 cmake(1) 程序）或 CMAKE_MESSAGE_LOG_LEVEL 变量来设置当前消息日志级别。

如果同时设置了命令行选项和变量，则命令行选项优先。如果两者都没有设置，则返回默认日志级别。

终止脚本¶

在 3.29 版本中添加。

cmake_language(EXIT <exit-code>)¶

终止当前 cmake -P 脚本并以 <exit-code> 退出。

此命令仅在脚本模式下有效。如果在其他上下文中使用，则会导致致命错误。

<exit-code> 应为非负数。如果 <exit-code> 为负数，则行为未定义（例如，在 Windows 上，错误代码 -1 将变为 0xffffffff，在 Linux 上则变为 255）。退出代码超过 255 可能不受底层 shell 或平台的支持，并且某些 shell 可能对超过 125 的值进行特殊解释。因此，建议仅在 0 到 125 的范围内指定 <exit-code>。

cmake_language¶

概要¶

简介¶

调用命令¶

评估代码¶

推迟调用¶

延迟调用示例¶

依赖项提供者¶

提供者命令¶

提供者示例¶

获取当前消息日志级别¶

终止脚本¶

目录

上一主题

下一主题

此页面