return

从文件、目录或函数返回。

return([PROPAGATE <var-name>...])

在包含的文件中遇到该命令时（通过 include() 或 find_package()），它会停止处理当前文件，并返回包含文件的控制权。如果它在另一个文件（例如 CMakeLists.txt）中未包含，则遇到它时，cmake_language(DEFER) 调度的延迟调用会被调用，并返回父目录的控制权（如果存在）。

如果在函数中调用 return()，控制权会返回该函数的调用者。请注意，与 function() 不同，macro() 会就地展开，因此不能处理 return()。

策略 CMP0140 控制有关命令参数的行为。除非策略设置为 NEW，否则会忽略所有参数。

PROPAGATE

在 3.25 版中添加。

该选项在父目录或函数调用者作用域中设置或取消设置指定的变量。这等效于 set(PARENT_SCOPE) 或 unset(PARENT_SCOPE) 命令，除了它与 block() 命令交互的方式，如下所述。

PROPAGATE 选项与 block() 命令结合使用时非常有用。return 将通过由 block() 命令创建的任何封闭块作用域传播指定的变量。在函数内部，此操作可确保将变量传播到函数的调用者，无论该函数中存不存在任何块。如果不在函数内部，则它可以确保将变量传播到父文件或目录作用域。例如：

CMakeLists.txt
cmake_minimum_required(VERSION 3.25)
project(example)

set(var1 "top-value")

block(SCOPE_FOR VARIABLES)
  add_subdirectory(subDir)
  # var1 has the value "block-nested"
endblock()

# var1 has the value "top-value"
subDir/CMakeLists.txt
function(multi_scopes result_var1 result_var2)
  block(SCOPE_FOR VARIABLES)
    # This would only propagate out of the immediate block, not to
    # the caller of the function.
    #set(${result_var1} "new-value" PARENT_SCOPE)
    #unset(${result_var2} PARENT_SCOPE)

    # This propagates the variables through the enclosing block and
    # out to the caller of the function.
    set(${result_var1} "new-value")
    unset(${result_var2})
    return(PROPAGATE ${result_var1} ${result_var2})
  endblock()
endfunction()

set(var1 "some-value")
set(var2 "another-value")

multi_scopes(var1 var2)
# Now var1 will hold "new-value" and var2 will be unset

block(SCOPE_FOR VARIABLES)
  # This return() will set var1 in the directory scope that included us
  # via add_subdirectory(). The surrounding block() here does not limit
  # propagation to the current file, but the block() in the parent
  # directory scope does prevent propagation going any further.
  set(var1 "block-nested")
  return(PROPAGATE var1)
endblock()

另请参阅