message

记录一条消息。

概要

General messages
  message([<mode>] "message text" ...)

Reporting checks
  message(<checkState> "message text" ...)

Configure Log
  message(CONFIGURE_LOG <text>...)

普通消息

message([<mode>] "message text" ...)

在日志中记录指定的消息文本。如果给定多个消息字符串，它们将被连接成单个消息，字符串之间没有分隔符。

可选的 <mode> 关键字确定消息的类型，这会影响消息的处理方式

FATAL_ERROR

CMake 错误，停止处理和生成。

cmake(1) 可执行文件将返回非零 退出代码。

SEND_ERROR

CMake 错误，继续处理，但跳过生成。

WARNING

CMake 警告，继续处理。

AUTHOR_WARNING

CMake 警告 (dev)，继续处理。

DEPRECATION

如果变量 CMAKE_ERROR_DEPRECATED 或 CMAKE_WARN_DEPRECATED 分别被启用，则提示 CMake 弃用错误或警告，否则不显示任何消息。

(none) 或 NOTICE

打印到 stderr 的重要消息，以引起用户的注意。

STATUS

项目用户可能感兴趣的主要信息消息。理想情况下，这些消息应当简洁，不超过一行，但仍然提供信息。

VERBOSE

面向项目用户、提供详细信息的消息。这些消息应当提供附加详细信息，它们在大多数情况下可能不重要，但在用户想要深入了解正在发生的事情时可能有用。

DEBUG

面向在项目自身上工作的开发者提供详细信息的消息，而不是面向只想构建项目的用户。这些消息通常与其他构建项目的用户无关，而且常常与内部实现细节紧密相关。

TRACE

提供非常底层的实现细节的细粒度消息。使用此日志级别的消息通常只是临时的，并期望在发布项目、打包文件等之前被删除。

在 3.15 版中添加： 添加了 NOTICE、VERBOSE、DEBUG 和 TRACE 级别。

CMake 命令行工具在 stdout 上显示 STATUS 到 TRACE 消息，消息前有连字符和空格。所有其他消息类型都被发送到 stderr，且没有连字符前缀。 CMake GUI，会在其日志区域中显示所有消息。 curses interface 在状态行上一次显示 STATUS 到 TRACE 消息，在交互式弹出框中显示其他消息。这些工具的每个 --log-level 命令行选项，都可以用于控制显示哪些消息。

在版本 3.17 中添加： 为了使日志级别在 CMake 运行之间保持不变，可以设置 CMAKE_MESSAGE_LOG_LEVEL 变量。请注意，命令行选项优先于缓存变量。

在版本 3.16 中添加： 日志级别为 NOTICE 及更低级别的消息，每一行都会在前加上 CMAKE_MESSAGE_INDENT 变量的内容（通过连接其列表项转换为单个字符串）。对于 STATUS 到 TRACE 消息，此缩进内容将插入连字符后。

在版本 3.17 中新增:日志级别为 NOTICE 及以下级别时，其每一行还可以以 [some.context.example] 形式的上下文信息做前缀。方括号中的内容是通过将 CMAKE_MESSAGE_CONTEXT 列表变量转换为用点分隔的字符串获得的。消息上下文会始终显示在自动添加的前导连字符之后，但显示在任何缩进内容之前。默认情况下，不会显示消息上下文，必须通过指定 cmake --log-context 命令行选项或将 CMAKE_MESSAGE_CONTEXT_SHOW 变量设置为 true 来明确启用它。有关使用示例，请参见 CMAKE_MESSAGE_CONTEXT 文档。

CMake 警告和错误消息文本使用简单的标记语言显示。非缩进文本以分隔符分隔的行内环绕段落格式显示。缩进文本被视为已预先格式化。

报告检查

在版本 3.17 中新增。

CMake 输出中的常见模式是指示某种检查开始的消息，然后是报告该检查结果的另一个消息。例如

message(STATUS "Looking for someheader.h")
#... do the checks, set checkSuccess with the result
if(checkSuccess)
  message(STATUS "Looking for someheader.h - found")
else()
  message(STATUS "Looking for someheader.h - not found")
endif()

可以使用 message() 命令的 CHECK_... 关键字形式更可靠且更方便地表示

message(<checkState> "message" ...)

其中 <checkState> 必须为以下之一

CHECK_START

记录有关即将执行的检查的简洁消息。

CHECK_PASS

记录检查的成功结果。

CHECK_FAIL

记录检查的失败结果。

记录检查结果时，该命令将重复尚未报告结果的最近启动检查中的消息，然后是一些分隔符字符，然后提供在 CHECK_PASS 或 CHECK_FAIL 关键字之后的消息文本。检查消息始终在 STATUS 日志级别报告。

检查可以嵌套，并且每个 CHECK_START 应该恰好有一个匹配的 CHECK_PASS 或 CHECK_FAIL。如果需要，CMAKE_MESSAGE_INDENT 变量还可以用于向嵌套检查添加缩进。例如

message(CHECK_START "Finding my things")
list(APPEND CMAKE_MESSAGE_INDENT "  ")
unset(missingComponents)

message(CHECK_START "Finding partA")
# ... do check, assume we find A
message(CHECK_PASS "found")

message(CHECK_START "Finding partB")
# ... do check, assume we don't find B
list(APPEND missingComponents B)
message(CHECK_FAIL "not found")

list(POP_BACK CMAKE_MESSAGE_INDENT)
if(missingComponents)
  message(CHECK_FAIL "missing components: ${missingComponents}")
else()
  message(CHECK_PASS "all components found")
endif()

以上命令输出类似于以下内容

-- Finding my things
--   Finding partA
--   Finding partA - found
--   Finding partB
--   Finding partB - not found
-- Finding my things - missing components: B

配置日志

3.26 版本新增。

message(CONFIGURE_LOG <text>...)

使用指定的 <文本> 记录 configure-log 消息事件。根据惯例，如果文本包含多行，则第一行应为事件的摘要。

此模式用于记录系统检查或其他由缓存项保护的一次性操作的详细信息，但不是使用 try_compile() 或 try_run() 执行的，这些函数会自动记录其详细信息。项目应避免每次运行 CMake 时都调用它。例如

if (NOT DEFINED MY_CHECK_RESULT)
  # Print check summary in configure output.
  message(CHECK_START "My Check")

  # ... perform system inspection, e.g., with execute_process ...

  # Cache the result so we do not run the check again.
  set(MY_CHECK_RESULT "${MY_CHECK_RESULT}" CACHE INTERNAL "My Check")

  # Record the check details in the cmake-configure-log.
  message(CONFIGURE_LOG
    "My Check Result: ${MY_CHECK_RESULT}\n"
    "${details}"
  )

  # Print check result in configure output.
  if(MY_CHECK_RESULT)
    message(CHECK_PASS "passed")
  else()
    message(CHECK_FAIL "failed")
  endif()
endif()

如果未配置任何项目，例如在 cmake -P 脚本模式中，则此命令什么都不做。

另请参见