message

记录一条消息。

概要

General messages
  message([<mode>] "message text" ...)

Reporting checks
  message(<checkState> "message text" ...)

Configure Log
  message(CONFIGURE_LOG <text>...)

常规消息

message([<mode>] "message text" ...)

将指定的消息文本记录到日志中。如果给出了多个消息字符串，它们将被连接成一条消息，且字符串之间没有分隔符。

可选的 <mode> 关键字决定了消息的类型，这会影响消息的处理方式：

FATAL_ERROR

CMake 错误，停止处理和生成。

cmake(1) 可执行文件将返回一个非零的 退出代码。

SEND_ERROR

CMake 错误，继续处理，但跳过生成。

WARNING

CMake 警告，继续处理。

AUTHOR_WARNING

CMake 警告（开发版），继续处理。

DEPRECATION

如果分别启用了变量 CMAKE_ERROR_DEPRECATED 或 CMAKE_WARN_DEPRECATED，则会出现 CMake 弃用错误或警告，否则不显示任何消息。

(无) 或 NOTICE

打印到 stderr 的重要消息，以引起用户注意。

STATUS

项目用户可能感兴趣的主要重要消息。理想情况下，这些消息应该简洁，不超过一行，但仍需具有信息量。

VERBOSE

针对项目用户的详细信息消息。这些消息应提供在大多数情况下无需关注，但在构建项目时若想深入了解发生了什么，可能会有用的额外细节。

DEBUG

针对开发该项目的开发人员（而非仅想构建它的用户）的详细信息消息。这些消息通常不会引起其他构建项目的用户的兴趣，并且通常与内部实现细节密切相关。

TRACE

具有极底层实现细节的细粒度消息。使用此日志级别的消息通常只是暂时的，预计在发布项目、打包文件等之前会被删除。

3.15 版本新增： 添加了 NOTICE, VERBOSE, DEBUG 和 TRACE 级别。

CMake 命令行工具将 STATUS 到 TRACE 级别的消息显示在 stdout 上，并在消息前加上两个连字符和一个空格。所有其他类型的消息都被发送到 stderr，且不会加上连字符前缀。CMake GUI 在其日志区域显示所有消息。curses 界面 在状态栏上一次显示一条 STATUS 到 TRACE 消息，其他消息则显示在交互式弹出框中。每个工具的 --log-level 命令行选项可用于控制显示哪些消息。

3.17 版本新增： 为了使日志级别在 CMake 运行之间保持持久，可以改为设置 CMAKE_MESSAGE_LOG_LEVEL 变量。请注意，命令行选项的优先级高于缓存变量。

3.16 版本新增： NOTICE 及以下日志级别的消息，其每一行前面都会加上 CMAKE_MESSAGE_INDENT 变量的内容（通过连接其列表项转换为单个字符串）。对于 STATUS 到 TRACE 消息，此缩进内容将插入到连字符之后。

3.17 版本新增： NOTICE 及以下日志级别的消息，每一行也可以加上形式为 [some.context.example] 的上下文。方括号内的内容是通过将 CMAKE_MESSAGE_CONTEXT 列表变量转换为点分隔的字符串来获得的。消息上下文将始终出现在任何缩进内容之前，但出现在任何自动添加的前导连字符之后。默认情况下，不显示消息上下文，必须通过给出 cmake --log-context 命令行选项或将 CMAKE_MESSAGE_CONTEXT_SHOW 变量设置为 true 来显式启用它。有关使用示例，请参阅 CMAKE_MESSAGE_CONTEXT 文档。

CMake 警告和错误消息文本使用简单的标记语言显示。非缩进文本格式化为由换行符分隔的自动换行段落。缩进文本被视为预格式化文本。

报告检查

在 3.17 版本中添加。

CMake 输出中的一种常见模式是显示一条指示某种检查开始的消息，随后是另一条报告该检查结果的消息。例如：

message(STATUS "Looking for someheader.h")
#... do the checks, set checkSuccess with the result
if(checkSuccess)
  message(STATUS "Looking for someheader.h - found")
else()
  message(STATUS "Looking for someheader.h - not found")
endif()

这可以使用 message() 命令的 CHECK_... 关键字形式更稳健且方便地表示：

message(<checkState> "message" ...)

其中 <checkState> 必须是以下之一：

CHECK_START

记录关于即将进行的检查的简洁消息。

CHECK_PASS

记录检查的成功结果。

CHECK_FAIL

记录检查的不成功结果。

记录检查结果时，命令会重复最近启动且尚未报告结果的检查消息，然后是一些分隔字符，接着是 CHECK_PASS 或 CHECK_FAIL 关键字之后提供的消息文本。检查消息始终以 STATUS 日志级别报告。

检查可以嵌套，每个 CHECK_START 应该有一个对应的 CHECK_PASS 或 CHECK_FAIL。如果需要，CMAKE_MESSAGE_INDENT 变量也可用于为嵌套检查添加缩进。例如：

message(CHECK_START "Finding my things")
list(APPEND CMAKE_MESSAGE_INDENT "  ")
unset(missingComponents)

message(CHECK_START "Finding partA")
# ... do check, assume we find A
message(CHECK_PASS "found")

message(CHECK_START "Finding partB")
# ... do check, assume we don't find B
list(APPEND missingComponents B)
message(CHECK_FAIL "not found")

list(POP_BACK CMAKE_MESSAGE_INDENT)
if(missingComponents)
  message(CHECK_FAIL "missing components: ${missingComponents}")
else()
  message(CHECK_PASS "all components found")
endif()

上述命令的输出如下所示：

-- Finding my things
--   Finding partA
--   Finding partA - found
--   Finding partB
--   Finding partB - not found
-- Finding my things - missing components: B

配置日志

3.26 版新增。

message(CONFIGURE_LOG <text>...)

使用指定的 <text> 记录 配置日志消息事件。按照惯例，如果文本包含多行，第一行应该是事件的摘要。

此模式旨在记录由缓存条目保护的系统检查或其他一次性操作的详细信息，但如果该操作不是使用 try_compile() 或 try_run() 执行的（因为它们会自动记录详细信息）。项目应避免在每次 CMake 运行时调用它。例如：

if (NOT DEFINED MY_CHECK_RESULT)
  # Print check summary in configure output.
  message(CHECK_START "My Check")

  # ... perform system inspection, e.g., with execute_process ...

  # Cache the result so we do not run the check again.
  set(MY_CHECK_RESULT "${MY_CHECK_RESULT}" CACHE INTERNAL "My Check")

  # Record the check details in the cmake-configure-log.
  message(CONFIGURE_LOG
    "My Check Result: ${MY_CHECK_RESULT}\n"
    "${details}"
  )

  # Print check result in configure output.
  if(MY_CHECK_RESULT)
    message(CHECK_PASS "passed")
  else()
    message(CHECK_FAIL "failed")
  endif()
endif()

如果当前没有正在配置的项目（例如在 cmake -P 脚本模式下），该命令不执行任何操作。

另请参阅