CheckStructHasMember

此模块提供了一个命令，用于检查结构体或类是否具有指定的成员变量。

在 CMake 项目中加载此模块，使用

include(CheckStructHasMember)

命令

此模块提供以下命令

check_struct_has_member

检查给定结构体或类是否具有指定成员变量（仅检查一次）

check_struct_has_member(
  <struct>
  <member>
  <headers>
  <variable>
  [LANGUAGE <language>]
)

此命令检查结构体或类 <struct> 在包含指定头文件 <headers> 后是否包含指定的 <member>，其中应声明原型。多个头文件可以作为字符串在一个参数中指定，使用分号分隔列表。结果存储在内部缓存变量 <variable> 中。

选项包括

LANGUAGE <language>

使用 <language> 编译器执行检查。可接受的值为 C 和 CXX。如果未指定，则默认为 C。

影响检查的变量

在调用此命令之前，可以设置以下变量来修改检查的运行方式

CMAKE_REQUIRED_FLAGS

一个以空格分隔的字符串，包含要传递给编译器的附加标志。一个分号分隔列表将不起作用。CMAKE_<LANG>_FLAGS 及其相关的特定配置变量 CMAKE_<LANG>_FLAGS_<CONFIG> 的内容将自动在此变量内容之前添加到编译器命令中。

CMAKE_REQUIRED_DEFINITIONS

一个分号分隔列表的编译器定义，每个定义形式为 -DFOO 或 -DFOO=bar。还会自动添加一个由检查命令的结果变量参数指定的名称的定义。

CMAKE_REQUIRED_INCLUDES

一个分号分隔列表的头文件搜索路径，要传递给编译器。这些将是唯一使用的头文件搜索路径；将忽略 INCLUDE_DIRECTORIES 目录属性的内容。

CMAKE_REQUIRED_LINK_OPTIONS

3.14 版新增。

一个分号分隔列表的选项，要添加到链接命令中（有关详细信息，请参阅 try_compile()）。

CMAKE_REQUIRED_LIBRARIES

一个分号分隔列表的库，要添加到链接命令中。这些可以是系统库的名称，也可以是导入目标（有关详细信息，请参阅 try_compile()）。

CMAKE_REQUIRED_LINK_DIRECTORIES

在版本 3.31 中添加。

一个分号分隔列表的库搜索路径，要传递给链接器（有关详细信息，请参阅 try_compile()）。

CMAKE_REQUIRED_QUIET

版本 3.1 中新增。

如果此变量评估为布尔真值，则与检查关联的所有状态消息都将被抑制。

示例

示例：检查 C 结构体成员

在以下示例中，此模块检查 C 结构体 timeval 在包含 <sys/select.h> 头文件后是否具有成员变量 tv_sec。检查结果存储在内部缓存变量 HAVE_TIMEVAL_TV_SEC 中。

include(CheckStructHasMember)

check_struct_has_member(
  "struct timeval"
  tv_sec
  sys/select.h
  HAVE_TIMEVAL_TV_SEC
)

示例：检查 C++ 结构体成员

在以下示例中，此模块检查 C++ 结构体 std::tm 在包含 <ctime> 头文件后是否具有成员变量 tm_gmtoff。检查结果存储在内部缓存变量 HAVE_TM_GMTOFF 中。

include(CheckStructHasMember)

check_struct_has_member(
  std::tm
  tm_gmtoff
  ctime
  HAVE_TM_GMTOFF
  LANGUAGE CXX
)

示例：使用编译定义进行独立检查

在以下示例中，使用 CMakePushCheckState 模块执行带临时修改的编译定义的检查

include(CheckStructHasMember)
include(CMakePushCheckState)

cmake_push_check_state(RESET)
  set(CMAKE_REQUIRED_DEFINITIONS -D_GNU_SOURCE)

  check_struct_has_member(
    "struct utsname"
    domainname
    sys/utsname.h
    HAVE_UTSNAME_DOMAINNAME
  )
cmake_pop_check_state()