CheckSourceRuns¶

3.19 版本新增。

该模块提供了一个命令，用于检查源代码是否可以构建和运行。

在 CMake 项目中加载此模块，使用

include(CheckSourceRuns)

命令¶

此模块提供以下命令

check_source_runs¶

检查给定源代码是否一次性编译并链接成可执行文件，然后可以运行

check_source_runs(<lang> <code> <variable> [SRC_EXT <extension>])

此命令检查一次，以确认 <code> 中提供的 <lang> 源代码是否可以构建、链接为可执行文件，然后运行。检查结果存储在由 <variable> 指定的内部缓存变量中。

参数为

<lang>: 要检查的源代码 <code> 的编程语言。支持的语言包括：C、CXX、CUDA、Fortran、HIP、OBJC 和 OBJCXX。

版本 3.21 新增：支持 HIP 语言。
<code>: 要测试的源代码。它必须包含一个有效的源程序。例如，它必须至少包含一个 main() 函数（在 C/C++ 中），或一个 program 单元（在 Fortran 中）。
<variable>: 内部缓存变量的名称，其中包含检查结果。如果代码构建并以退出代码 0 成功运行，则用布尔真值表示成功。构建或运行失败用布尔假值表示，例如空字符串或错误消息。
SRC_EXT <extension>: 默认情况下，用于检查的内部测试源文件将获得与请求语言匹配的文件扩展名（例如，C 为 .c，C++ 为 .cxx，Fortran 为 .F90 等）。此选项可用于将其覆盖为 .<extension>。

影响检查的变量

在调用此命令之前，可以设置以下变量来修改检查的运行方式

CMAKE_REQUIRED_FLAGS: 一个空格分隔的字符串，包含要传递给编译器的附加标志。分号分隔的列表将不起作用。CMAKE_<LANG>_FLAGS 及其相关的特定于配置的 CMAKE_<LANG>_FLAGS_<CONFIG> 变量的内容会自动添加到编译器命令的前面，然后是此变量的内容。

CMAKE_REQUIRED_DEFINITIONS: 一个分号分隔的编译器定义列表，每个定义的形式为 -DFOO 或 -DFOO=bar。还会自动添加一个由检查命令的结果变量参数指定的名称的定义。

CMAKE_REQUIRED_INCLUDES: 一个分号分隔的头文件搜索路径列表，用于传递给编译器。这些将是唯一使用的头文件搜索路径；INCLUDE_DIRECTORIES 目录属性的内容将被忽略。

CMAKE_REQUIRED_LINK_OPTIONS: 3.14 版新增。

一个分号分隔的选项列表，用于添加到链接命令（有关更多详细信息，请参见try_compile()）。

CMAKE_REQUIRED_LIBRARIES: 一个分号分隔的库列表，用于添加到链接命令。这些可以是系统库的名称，也可以是导入目标（有关更多详细信息，请参见try_compile()）。

CMAKE_REQUIRED_LINK_DIRECTORIES: 在版本 3.31 中添加。

一个分号分隔的库搜索路径列表，用于传递给链接器（有关更多详细信息，请参见try_compile()）。

CMAKE_REQUIRED_QUIET: 版本 3.1 中新增。

如果此变量评估为布尔真值，则与检查关联的所有状态消息都将被抑制。

示例¶

示例：基本用法¶

以下示例演示了如何使用此模块检查 C 源代码在运行时是否受支持且可操作。检查结果存储在内部缓存变量 HAVE_NORETURN 中。

include(CheckSourceRuns)

check_source_runs(C "
  #include <stdlib.h>
  #include <stdnoreturn.h>
  noreturn void f(){ exit(0); }
  int main(void) { f(); return 1; }
" HAVE_NORETURN)

示例：检查 Fortran 代码¶

检查 Fortran 源代码是否成功运行

include(CheckSourceRuns)

check_source_runs(Fortran "
  program test
  real :: x[*]
  call co_sum(x)
  end program
" HAVE_COARRAY)

示例：检查带方括号参数的 C++ 代码¶

以下示例演示了如何检查 C++ 标准库是否功能正常，以及 std::vector 在运行时是否可用。如果源代码成功编译、链接并运行，则内部缓存变量 HAVE_WORKING_STD_VECTOR 将设置为布尔真值。代码使用方括号参数提供，以便更轻松地处理嵌入式引号

include(CheckSourceRuns)

check_source_runs(CXX [[
  #include <iostream>
  #include <vector>

  int main()
  {
    std::vector<int> v = {1, 2, 3};
    if (v.size() != 3) return 1;
    std::cout << "Vector works correctly." << std::endl;
    return 0;
  }
]] HAVE_WORKING_STD_VECTOR)

示例：独立检查¶

在以下示例中，此模块与 CMakePushCheckState 模块结合使用，以修改所需的编译定义和库，同时检查 C 函数 sched_getcpu() 在运行时是否受支持且可操作。例如，在某些系统上，sched_getcpu() 函数在编译时可能可用，但实际上并未由内核实现。在这种情况下，它返回 -1 并将 errno 设置为 ENOSYS。此检查验证 sched_getcpu() 是否成功运行，并将布尔结果存储在内部缓存变量 HAVE_SCHED_GETCPU 中。

include(CheckSourceRuns)
include(CMakePushCheckState)

cmake_push_check_state(RESET)
  set(CMAKE_REQUIRED_DEFINITIONS -D_GNU_SOURCE)

  if(CMAKE_SYSTEM_NAME STREQUAL "Haiku")
    set(CMAKE_REQUIRED_LIBRARIES gnu)
  endif()

  check_source_runs(C "
    #include <sched.h>
    int main(void)
    {
      if (sched_getcpu() == -1) {
        return 1;
      }
      return 0;
    }
  " HAVE_SCHED_GETCPU)
cmake_pop_check_state()

另请参阅¶

模块 CheckSourceCompiles 用于检查源代码是否可以构建。