foreach¶
为列表中的每个值评估一组命令。
foreach(<loop_var> <items>)
<commands>
endforeach()
其中 <items> 是由分号或空格分隔的项目列表。 foreach 和匹配的 endforeach 之间的所有命令都会被记录下来，但不会被调用。一旦 endforeach 被评估，记录的命令列表就会为 <items> 中的每个项目调用一次。在每次迭代开始时，变量 <loop_var> 将被设置为当前项目的值。
<loop_var> 的作用域仅限于循环作用域。有关详细信息，请参阅策略 CMP0124。
命令 break() 和 continue() 提供了逃离正常控制流的手段。
出于历史原因，endforeach() 命令接受一个可选的 <loop_var> 参数。如果使用，它必须是与打开的 foreach 命令的参数完全相同的重复。
foreach(<loop_var> RANGE <stop>)
在此变体中，foreach 迭代从 0、1、... 直到（包括）非负整数 <stop> 的数字。
foreach(<loop_var> RANGE <start> <stop> [<step>])
在此变体中，foreach 以 <step> 的步长从 <start> 迭代到最多 <stop>。如果未指定 <step>，则步长为 1。三个参数 <start> <stop> <step> 都必须是非负整数，并且 <stop> 不能小于 <start>；否则，您将进入未记录行为的危险区域，该行为在未来版本中可能会发生变化。
foreach(<loop_var> IN [LISTS [<lists>]] [ITEMS [<items>]])
在此变体中，<lists> 是一个由列表值变量组成的空格或分号分隔的列表。 foreach 命令迭代给定列表中的每个项目。 ITEMS 关键字后面的 <items> 会像第一个变体中的 foreach 命令一样被处理。 LISTS A 和 ITEMS ${A} 这两种形式是等效的。如果没有给出 <lists> 或 <items>，循环体将永远不会被执行（即，它被处理为空）。
以下示例显示了如何处理 LISTS 选项
set(A 0;1)
set(B 2 3)
set(C "4 5")
set(D 6;7 8)
set(E "")
foreach(X IN LISTS A B C D E)
message(STATUS "X=${X}")
endforeach()
产生
-- X=0
-- X=1
-- X=2
-- X=3
-- X=4 5
-- X=6
-- X=7
-- X=8
foreach(<loop_var>... IN ZIP_LISTS <lists>)
在 3.17 版本中添加。
在此变体中，<lists> 是一个由列表值变量组成的空格或分号分隔的列表。 foreach 命令会同时迭代每个列表，并进行如下设置迭代变量：
如果给出了单个
loop_var，则它会将一系列loop_var_N变量设置为相应列表的当前项目；如果传递了多个变量名，它会将每个变量设置为相应列表的当前项目。迭代变量的数量必须与列表变量的数量匹配。
如果没有给出 <lists>，循环体将永远不会被执行（即，它被处理为空）。
以下示例显示了如何处理 ZIP_LISTS 选项
list(APPEND English one two three four)
list(APPEND Bahasa satu dua tiga)
foreach(num IN ZIP_LISTS English Bahasa)
message(STATUS "num_0=${num_0}, num_1=${num_1}")
endforeach()
foreach(en ba IN ZIP_LISTS English Bahasa)
message(STATUS "en=${en}, ba=${ba}")
endforeach()
产生
-- num_0=one, num_1=satu
-- num_0=two, num_1=dua
-- num_0=three, num_1=tiga
-- num_0=four, num_1=
-- en=one, ba=satu
-- en=two, ba=dua
-- en=three, ba=tiga
-- en=four, ba=