CheckFunctionExists

此模块提供了一个命令来检查 C 函数是否存在。

在 CMake 项目中加载此模块，使用

include(CheckFunctionExists)

命令

此模块提供以下命令

check_function_exists

检查一次 C 函数是否可以从系统库中链接

check_function_exists(<function> <variable>)

此命令检查系统上的库是否提供了 <function>，并将结果存储在内部缓存变量 <variable> 中。

注意

出于以下原因，建议使用 CheckSymbolExists 或 CheckSourceCompiles 而非此命令

  • check_function_exists() 无法检测内联在头文件中的函数或定义为预处理器宏的函数。

  • check_function_exists() 无法检测 Win32 API 的 32 位版本中的任何内容，因为调用约定不匹配。

  • check_function_exists() 仅验证链接，它不验证函数是否在系统头文件中声明。

影响检查的变量

在调用此命令之前，可以设置以下变量来修改检查的运行方式

CMAKE_REQUIRED_FLAGS

要传递给编译器的附加标志的空格分隔字符串。 分号分隔列表 将不起作用。 CMAKE_<LANG>_FLAGS 变量及其相关的配置特定 CMAKE_<LANG>_FLAGS_<CONFIG> 变量的内容会自动在编译器命令前加上此变量的内容。

CMAKE_REQUIRED_DEFINITIONS

分号分隔的编译器定义列表，每个定义的形式为 -DFOO 或 -DFOO=bar。还将自动添加对检查命令的 result variable 参数指定的名称的定义。

CMAKE_REQUIRED_INCLUDES

要传递给编译器的头文件搜索路径的分号分隔列表。这些将是唯一使用的头文件搜索路径；将忽略 INCLUDE_DIRECTORIES 目录属性的内容。

CMAKE_REQUIRED_LINK_OPTIONS

3.14 版新增。

要添加到链接命令的选项的分号分隔列表（有关更多详细信息，请参阅 try_compile()）。

CMAKE_REQUIRED_LIBRARIES

要添加到链接命令的库的分号分隔列表。这些可以是系统库的名称，也可以是 导入的目标（有关更多详细信息，请参阅 try_compile()）。

CMAKE_REQUIRED_LINK_DIRECTORIES

在版本 3.31 中添加。

要传递给链接器的库搜索路径的分号分隔列表（有关更多详细信息，请参阅 try_compile()）。

CMAKE_REQUIRED_QUIET

版本 3.1 中新增。

如果此变量评估为布尔真值，则与检查关联的所有状态消息都将被抑制。

示例

示例：基本用法

在下面的示例中，执行一个检查以确定链接器是否可以看到 C 函数 fopen()，并将结果存储在 HAVE_FOPEN 内部缓存变量中

include(CheckFunctionExists)

check_function_exists(fopen HAVE_FOPEN)

示例：缺少声明

如上所述，首选 CheckSymbolExists 模块来检查 C 函数，因为它还会验证函数是否被声明或定义为宏。 在下面的示例中，此模块用于检查一个函数可能未在系统头文件中声明的边缘情况。 例如，在 macOS 上，fdatasync() 函数可能在 C 库中可用，但其声明并未在 unistd.h 系统头文件中提供。

CMakeLists.txt
include(CheckFunctionExists)
include(CheckSymbolExists)

check_symbol_exists(fdatasync "unistd.h" HAVE_FDATASYNC)

# Check if fdatasync() is available in the C library.
if(NOT HAVE_FDATASYNC)
  check_function_exists(fdatasync HAVE_FDATASYNC_WITHOUT_DECL)
endif()

在这种情况下，项目可以提供自己的声明（如果缺失）

example.c
#ifdef HAVE_FDATASYNC_WITHOUT_DECL
  extern int fdatasync(int);
#endif

另请参阅