block

在 3.25 版本中新增。

使用专用的变量和/或策略范围来评估一组命令。

block([SCOPE_FOR [POLICIES] [VARIABLES]] [PROPAGATE <var-name>...])
  <commands>
endblock()

在 block() 和匹配的 endblock() 之间的所有命令都将被记录，但不会被调用。一旦 endblock() 被评估，记录的命令列表将在请求的范围内调用，然后删除由 block() 命令创建的范围。

SCOPE_FOR

指定必须创建哪些范围。

POLICIES

创建一个新的策略范围。这等同于 cmake_policy(PUSH)，并在离开块范围时自动执行 cmake_policy(POP)。

VARIABLES

创建一个新的变量作用域。

如果未指定 SCOPE_FOR，则等同于

block(SCOPE_FOR VARIABLES POLICIES)

PROPAGATE

当 block() 命令创建变量作用域时，此选项会在父作用域中设置或取消设置指定的变量。这等同于 set(PARENT_SCOPE) 或 unset(PARENT_SCOPE) 命令。

set(var1 "INIT1")
set(var2 "INIT2")
set(var3 "INIT3")

block(PROPAGATE var1 var2)
  set(var1 "VALUE1")
  unset(var2)
  set(var3 "VALUE3")
endblock()

# Now var1 holds VALUE1, var2 is unset, and var3 holds the initial value INIT3

此选项仅在创建变量作用域时允许。在其他情况下将引发错误。

当 block() 位于 foreach() 或 while() 命令内部时，可以在块内使用 break() 和 continue() 命令。

while(TRUE)
  block()
     ...
     # the break() command will terminate the while() command
     break()
  endblock()
endwhile()

另请参阅

• endblock()

• return()

• cmake_policy()