步骤 4：添加生成器表达式¶
生成器表达式 在构建系统生成期间进行评估，以生成特定于每个构建配置的信息。
生成器表达式 允许在许多目标属性的上下文中使用，例如 LINK_LIBRARIES、INCLUDE_DIRECTORIES、COMPILE_DEFINITIONS 等。它们也可以在使用命令填充这些属性时使用，例如 target_link_libraries()、target_include_directories()、target_compile_definitions() 等。
生成器表达式 可用于启用条件链接、编译时使用的条件定义、条件包含目录等。条件可以基于构建配置、目标属性、平台信息或任何其他可查询信息。
生成器表达式 有不同的类型，包括逻辑表达式、信息表达式和输出表达式。
逻辑表达式用于创建条件输出。基本表达式是 0 和 1 表达式。$<0:...> 结果为空字符串，而 $<1:...> 结果为 ... 的内容。它们也可以嵌套。
练习 1 - 使用生成器表达式添加编译器警告标志¶
生成器表达式 的常见用法是有条件地添加编译器标志，例如用于语言级别或警告的标志。一个很好的模式是将此信息关联到 INTERFACE 目标，从而允许此信息传播。
目标¶
在构建时添加编译器警告标志，但不用于已安装的版本。
有用资源¶
要编辑的文件¶
CMakeLists.txt
开始¶
打开文件 Step4/CMakeLists.txt 并完成 TODO 1 到 TODO 4。
首先，在顶层 CMakeLists.txt 文件中，我们需要将 cmake_minimum_required() 设置为 3.15。在此练习中，我们将使用在 CMake 3.15 中引入的生成器表达式。
接下来，我们添加我们项目所需的编译器警告标志。由于警告标志因编译器而异，我们使用 COMPILE_LANG_AND_ID 生成器表达式来控制在给定语言和一组编译器 ID 的情况下应用哪些标志。
构建并运行¶
创建一个名为 Step4_build 的新目录，运行 cmake 可执行文件或 cmake-gui 来配置项目，然后使用您选择的构建工具或从构建目录使用 cmake --build . 来构建它。
mkdir Step4_build
cd Step4_build
cmake ../Step4
cmake --build .
解决方案¶
将 cmake_minimum_required() 更新为至少需要 CMake 版本 3.15
TODO 1：点击显示/隐藏答案
cmake_minimum_required(VERSION 3.15)
接下来，我们确定系统当前使用哪个编译器进行构建，因为警告标志会因我们使用的编译器而异。这是通过 COMPILE_LANG_AND_ID 生成器表达式完成的。我们将结果设置在变量 gcc_like_cxx 和 msvc_cxx 中，如下所示
TODO 2：点击显示/隐藏答案
set(gcc_like_cxx "$<COMPILE_LANG_AND_ID:CXX,ARMClang,AppleClang,Clang,GNU,LCC>")
set(msvc_cxx "$<COMPILE_LANG_AND_ID:CXX,MSVC>")
接下来，我们添加我们项目所需的编译器警告标志。使用我们的变量 gcc_like_cxx 和 msvc_cxx，我们可以使用另一个生成器表达式来仅当变量为真时应用相应的标志。我们使用 target_compile_options() 将这些标志应用于我们的接口库。
TODO 3：点击显示/隐藏答案
target_compile_options(tutorial_compiler_flags INTERFACE
"$<${gcc_like_cxx}:-Wall;-Wextra;-Wshadow;-Wformat=2;-Wunused>"
"$<${msvc_cxx}:-W3>"
)
最后，我们只希望这些警告标志在构建期间使用。我们已安装项目的消费者不应继承我们的警告标志。为了指定这一点，我们使用 BUILD_INTERFACE 条件将 TODO 3 中的标志包装在生成器表达式中。最终的完整代码如下所示
TODO 4：点击显示/隐藏答案
target_compile_options(tutorial_compiler_flags INTERFACE
"$<${gcc_like_cxx}:$<BUILD_INTERFACE:-Wall;-Wextra;-Wshadow;-Wformat=2;-Wunused>>"
"$<${msvc_cxx}:$<BUILD_INTERFACE:-W3>>"
)