步骤11：添加导出配置¶

在本教程的安装和测试部分，我们添加了CMake安装项目库和头文件的功能。在打包安装程序部分，我们添加了打包这些信息的功能，以便将其分发给其他人。

下一步是添加必要的信息，以便其他CMake项目可以使用我们的项目，无论是从构建目录、本地安装还是打包后。

第一步是更新我们的install(TARGETS)命令，不仅指定DESTINATION，还指定EXPORT。EXPORT关键字生成一个CMake文件，其中包含从安装树导入安装命令中列出的所有目标的代码。所以，让我们继续显式地EXPORT MathFunctions库，更新MathFunctions/CMakeLists.txt中的install命令，使其看起来像

MathFunctions/CMakeLists.txt¶

set(installable_libs MathFunctions tutorial_compiler_flags)
if(TARGET SqrtLibrary)
  list(APPEND installable_libs SqrtLibrary)
endif()
install(TARGETS ${installable_libs}
        EXPORT MathFunctionsTargets
        DESTINATION lib)
# install include headers
install(FILES MathFunctions.h DESTINATION include)

现在我们已经导出了MathFunctions，我们还需要显式安装生成的MathFunctionsTargets.cmake文件。这通过在顶级CMakeLists.txt的底部添加以下内容来完成

CMakeLists.txt¶

install(EXPORT MathFunctionsTargets
  FILE MathFunctionsTargets.cmake
  DESTINATION lib/cmake/MathFunctions
)

此时您应该尝试运行CMake。如果一切设置正确，您将看到CMake会生成一个错误，看起来像

Target "MathFunctions" INTERFACE_INCLUDE_DIRECTORIES property contains
path:

  "/Users/robert/Documents/CMakeClass/Tutorial/Step11/MathFunctions"

which is prefixed in the source directory.

CMake告诉您，在生成导出信息时，它将导出一个与当前机器固有绑定的路径，并且在其他机器上将无效。解决方案是更新MathFunctions的target_include_directories()，使其理解在构建目录中和安装/打包后使用时需要不同的INTERFACE位置。这意味着将MathFunctions的target_include_directories()调用转换为

MathFunctions/CMakeLists.txt¶

target_include_directories(MathFunctions
                           INTERFACE
                            $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>
                            $<INSTALL_INTERFACE:include>
                           )

更新后，我们可以重新运行CMake并验证它不再发出警告。

此时，我们已经正确打包了所需的CMake目标信息，但我们仍然需要生成一个MathFunctionsConfig.cmake文件，以便CMake的find_package()命令可以找到我们的项目。所以，让我们在项目顶级添加一个名为Config.cmake.in的新文件，内容如下

Config.cmake.in¶

@PACKAGE_INIT@

include ( "${CMAKE_CURRENT_LIST_DIR}/MathFunctionsTargets.cmake" )

然后，要正确配置和安装该文件，请在顶级CMakeLists.txt的底部添加以下内容

CMakeLists.txt¶

install(EXPORT MathFunctionsTargets
  FILE MathFunctionsTargets.cmake
  DESTINATION lib/cmake/MathFunctions
)

include(CMakePackageConfigHelpers)

接下来，我们执行configure_package_config_file()。此命令将配置提供的文件，但与标准configure_file()方式有一些特定的差异。为了正确使用此函数，输入文件除了所需内容外，应该有一行包含文本@PACKAGE_INIT@。该变量将被一个代码块替换，该代码块将设置的值转换为相对路径。这些新值可以引用相同的名称，但前缀为PACKAGE_。

CMakeLists.txt¶

install(EXPORT MathFunctionsTargets
  FILE MathFunctionsTargets.cmake
  DESTINATION lib/cmake/MathFunctions
)

include(CMakePackageConfigHelpers)
# generate the config file that includes the exports
configure_package_config_file(${CMAKE_CURRENT_SOURCE_DIR}/Config.cmake.in
  "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfig.cmake"
  INSTALL_DESTINATION "lib/cmake/MathFunctions"
  NO_SET_AND_CHECK_MACRO
  NO_CHECK_REQUIRED_COMPONENTS_MACRO
  )

接下来是write_basic_package_version_file()。此命令写入一个文件，该文件由find_package()使用，记录所需包的版本和兼容性。在这里，我们使用Tutorial_VERSION_*变量，并表示它与AnyNewerVersion兼容，这表示此版本或任何更高版本都与请求的版本兼容。

CMakeLists.txt¶

write_basic_package_version_file(
  "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfigVersion.cmake"
  VERSION "${Tutorial_VERSION_MAJOR}.${Tutorial_VERSION_MINOR}"
  COMPATIBILITY AnyNewerVersion
)

最后，设置两个生成的文件都将被安装

CMakeLists.txt¶

install(FILES
  ${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfig.cmake
  ${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsConfigVersion.cmake
  DESTINATION lib/cmake/MathFunctions
  )

此时，我们已经为我们的项目生成了一个可重定位的CMake配置，可以在项目安装或打包后使用。如果我们也希望我们的项目可以从构建目录中使用，我们只需在顶级CMakeLists.txt的底部添加以下内容

CMakeLists.txt¶

export(EXPORT MathFunctionsTargets
  FILE "${CMAKE_CURRENT_BINARY_DIR}/MathFunctionsTargets.cmake"
)

通过此导出调用，我们现在生成一个MathFunctionsTargets.cmake，允许构建目录中配置的MathFunctionsConfig.cmake被其他项目使用，而无需安装。

步骤11：添加导出配置¶

上一主题

下一主题

本页