foreach¶
对列表中的每个值评估一组命令。
foreach(<loop_var> <items>)
<commands>
endforeach()
其中 <items> 是由分号或空格分隔的项目列表。在 foreach 和匹配的 endforeach 之间的所有命令都会被记录，而不会被调用。一旦 endforeach 被评估，记录的命令列表会为 <items> 中的每个项目调用一次。在每次迭代开始时，变量 <loop_var> 将被设置为当前项目的值。
<loop_var> 的作用域仅限于循环作用域。详见策略 CMP0124。
命令 break() 和 continue() 提供了跳出正常控制流的方法。
根据遗留规定，endforeach() 命令允许一个可选的 <loop_var> 参数。如果使用，它必须与开头的 foreach 命令的参数完全相同。
foreach(<loop_var> RANGE <stop>)
在此变体中，foreach 迭代数字 0, 1, ... 直到（包括）非负整数 <stop>。
foreach(<loop_var> RANGE <start> <stop> [<step>])
在此变体中，foreach 从 <start> 开始迭代，以 <step> 为步长，最多迭代到 <stop>。如果未指定 <step>，则步长为 1。三个参数 <start> <stop> <step> 都必须是非负整数，并且 <stop> 不能小于 <start>；否则将进入未文档化行为的危险区域，该行为可能会在未来的版本中更改。
foreach(<loop_var> IN [LISTS [<lists>]] [ITEMS [<items>]])
在此变体中，<lists> 是由空格或分号分隔的列表值变量列表。foreach 命令迭代每个给定列表中的每个项目。关键字 ITEMS 后面的 <items> 按照 foreach 命令的第一个变体进行处理。形式 LISTS A 和 ITEMS ${A} 是等效的。
以下示例展示了 LISTS 选项是如何处理的
set(A 0;1)
set(B 2 3)
set(C "4 5")
set(D 6;7 8)
set(E "")
foreach(X IN LISTS A B C D E)
message(STATUS "X=${X}")
endforeach()
产生
-- X=0
-- X=1
-- X=2
-- X=3
-- X=4 5
-- X=6
-- X=7
-- X=8
foreach(<loop_var>... IN ZIP_LISTS <lists>)
在 3.17 版本中添加。
在此变体中，<lists> 是由空格或分号分隔的列表值变量列表。foreach 命令同时迭代每个列表，并按如下方式设置迭代变量
如果只给出了一个
loop_var，则它会将一系列loop_var_N变量设置为相应列表中的当前项目；如果传递了多个变量名，它们的数量应与列表变量的数量匹配；
如果任何列表较短，则当前迭代的相应迭代变量未定义。
list(APPEND English one two three four)
list(APPEND Bahasa satu dua tiga)
foreach(num IN ZIP_LISTS English Bahasa)
message(STATUS "num_0=${num_0}, num_1=${num_1}")
endforeach()
foreach(en ba IN ZIP_LISTS English Bahasa)
message(STATUS "en=${en}, ba=${ba}")
endforeach()
产生
-- num_0=one, num_1=satu
-- num_0=two, num_1=dua
-- num_0=three, num_1=tiga
-- num_0=four, num_1=
-- en=one, ba=satu
-- en=two, ba=dua
-- en=three, ba=tiga
-- en=four, ba=