CMAKE_<LANG>_LINK_GROUP_USING_<FEATURE>

在 3.24 版本中添加。

此变量定义了在使用 LINK_GROUP 生成器表达式且目标链接语言为 <LANG> 时，如何链接指定 <FEATURE> 的库组。为了使此变量生效，必须将关联的 CMAKE_<LANG>_LINK_GROUP_USING_<FEATURE>_SUPPORTED 变量设置为 true。

对于与链接语言无关的特性，应改用 CMAKE_LINK_GROUP_USING_<FEATURE> 变量。

功能名称区分大小写，并且只能包含字母、数字和下划线。所有大写字母的功能名称保留给 CMake 自身的内置功能（请参阅下面的 预定义功能）。

功能定义

组特性定义是一个包含正好两个元素的列表

<PREFIX> <SUFFIX>

在链接器命令行上，<PREFIX> 将出现在组库列表之前，<SUFFIX> 将出现在列表之后。

对于此变量的元素，可以使用 LINKER: 前缀。

为了将选项传递给链接器工具，每个编译器驱动程序都有其自己的语法。可以使用 LINKER: 前缀和 , 分隔符以可移植的方式指定要传递给链接器工具的选项。LINKER: 将被替换为适当的驱动程序选项，, 被替换为适当的驱动程序分隔符。驱动程序前缀和驱动程序分隔符由 CMAKE_<LANG>_LINKER_WRAPPER_FLAG 和 CMAKE_<LANG>_LINKER_WRAPPER_FLAG_SEP 变量的值提供。

例如，对于 Clang，"LINKER:-z,defs" 会变成 -Xlinker -z -Xlinker defs；对于 GNU GCC，则会变成 -Wl,-z,defs。

LINKER: 前缀可以作为 SHELL: 前缀表达式的一部分指定。

LINKER: 前缀支持使用 SHELL: 前缀和空格作为分隔符来指定参数，作为一种替代语法。前面的示例将变为 "LINKER:SHELL:-z defs"。

注意

不支持在 LINKER: 前缀的开头以外的任何位置指定 SHELL: 前缀。

示例

解决两个静态库之间的交叉引用

一个项目可能定义了两个或多个具有相互循环依赖的静态库。为了让链接器在链接时解析所有符号，它可能需要在库之间反复搜索，直到不再创建新的未定义引用。不同的链接器使用不同的语法来实现这一点。下面的示例展示了如何为某些链接器实现这一点。请注意，这仅用于说明目的。项目应使用内置的 RESCAN 组特性（参见 预定义特性），它提供了此功能更完整、更健壮的实现。

set(CMAKE_C_LINK_GROUP_USING_cross_refs_SUPPORTED TRUE)
if(CMAKE_C_COMPILER_ID STREQUAL "GNU" AND CMAKE_SYSTEM_NAME STREQUAL "Linux")
  set(CMAKE_C_LINK_GROUP_USING_cross_refs
    "LINKER:--start-group"
    "LINKER:--end-group"
  )
elseif(CMAKE_C_COMPILER_ID STREQUAL "SunPro" AND CMAKE_SYSTEM_NAME STREQUAL "SunOS")
  set(CMAKE_C_LINK_GROUP_USING_cross_refs
    "LINKER:-z,rescan-start"
    "LINKER:-z,rescan-end"
  )
else()
  # feature not yet supported for the other environments
  set(CMAKE_C_LINK_GROUP_USING_cross_refs_SUPPORTED FALSE)
endif()

add_library(lib1 STATIC ...)
add_library(lib2 SHARED ...)

if(CMAKE_C_LINK_GROUP_USING_cross_refs_SUPPORTED)
  target_link_libraries(lib2 PRIVATE "$<LINK_GROUP:cross_refs,lib1,external>")
else()
  target_link_libraries(lib2 PRIVATE lib1 external)
endif()

CMake 在链接 lib2 时将生成以下链接器命令行片段

• GNU: -Wl,--start-group /path/to/lib1.a -lexternal -Wl,--end-group

• SunPro: -Wl,-z,rescan-start /path/to/lib1.a -lexternal -Wl,-z,rescan-end

预定义功能

以下是 CMake 预定义的内置组特性

RESCAN

有些链接器是单次扫描的。对于这些链接器，库之间的循环引用通常会导致未解析的符号。此特性指示链接器反复搜索指定的静态库，直到没有新的未定义引用被创建。

通常，静态库只在命令行上指定的顺序中被搜索一次。如果该库中的某个符号需要解析由命令行上稍后出现的库中的对象引用的未定义符号，链接器将无法解析该引用。通过使用 RESCAN 特性对静态库进行分组，它们将被反复搜索，直到所有可能的引用都被解析。这将使用诸如 --start-group 和 --end-group 的链接器选项，或者在 SunOS 上使用 -z rescan-start 和 -z rescan-end。

使用此功能会带来显著的性能成本。最好仅在两个或多个静态库之间存在不可避免的循环引用时才使用它。

此功能在使用针对 Linux、BSD 和 SunOS 的工具链时可用。在使用 GNU 工具链时，也可以在针对 Windows 平台时使用。