WriteCompilerDetectionHeader

版本 3.20 中已弃用: 此模块仅在策略 CMP0120 未设置为 NEW 时可用。请勿在新代码中使用它。

在版本 3.1 中添加。

此模块提供函数 write_compiler_detection_header()。

此函数可用于生成一个适用于预处理器包含的文件，其中包含可在源代码中使用的宏

write_compiler_detection_header(
          FILE <file>
          PREFIX <prefix>
          [OUTPUT_FILES_VAR <output_files_var> OUTPUT_DIR <output_dir>]
          COMPILERS <compiler> [...]
          FEATURES <feature> [...]
          [BARE_FEATURES <feature> [...]]
          [VERSION <version>]
          [PROLOG <prolog>]
          [EPILOG <epilog>]
          [ALLOW_UNKNOWN_COMPILERS]
          [ALLOW_UNKNOWN_COMPILER_VERSIONS]
)

这将生成文件 <file>，其中的宏都带有前缀 <prefix>。

默认情况下，所有内容都直接写入 <file>。OUTPUT_FILES_VAR 可以指定将编译器特定的内容写入单独的文件。然后，单独的文件在 <output_files_var> 中可用，并且可以被调用者使用，例如用于安装。OUTPUT_DIR 指定从主 <file> 到编译器特定文件的相对路径。例如

write_compiler_detection_header(
  FILE climbingstats_compiler_detection.h
  PREFIX ClimbingStats
  OUTPUT_FILES_VAR support_files
  OUTPUT_DIR compilers
  COMPILERS GNU Clang MSVC Intel
  FEATURES cxx_variadic_templates
)
install(FILES
  ${CMAKE_CURRENT_BINARY_DIR}/climbingstats_compiler_detection.h
  DESTINATION include
)
install(FILES
  ${support_files}
  DESTINATION include/compilers
)

VERSION 可用于指定要生成的 API 版本。CMake 的未来版本可能会引入替代 API。通过任何大于或等于引入给定 API 的 CMake 版本且小于引入其后续 API 的 CMake 版本的 <version> 值来选择给定的 API。如果未指定显式版本，则使用变量 CMAKE_MINIMUM_REQUIRED_VERSION 的值。（截至 CMake 版本 4.0.0，只有一个 API 版本。）

PROLOG 可以指定为要在标头开头写入的文本内容。EPILOG 可以指定为要在标头末尾写入的文本内容

必须至少列出一个 <compiler> 和一个 <feature>。CMake 已知但未指定的编译器将被检测到，并为它们生成预处理器 #error。为 CMake 已知的每个编译器生成与 <PREFIX>_COMPILER_IS_<compiler> 匹配的预处理器宏，以包含值 0 或 1。

可能的编译器标识符在变量 CMAKE_<LANG>_COMPILER_ID 中记录。此 CMake 版本中可用的功能在全局属性 CMAKE_C_KNOWN_FEATURES 和 CMAKE_CXX_KNOWN_FEATURES 中列出。有关编译功能的更多信息，请参阅 cmake-compile-features(7) 手册。

在版本 3.2 中添加: 添加了 MSVC 和 AppleClang 编译器支持。

在版本 3.6 中添加: 添加了 Intel 编译器支持。

在版本 3.8 中更改: 如果请求，则忽略 {c,cxx}_std_* 元功能。

在版本 3.8 中添加: ALLOW_UNKNOWN_COMPILERS 和 ALLOW_UNKNOWN_COMPILER_VERSIONS 使模块生成将未知编译器视为仅缺少所有功能的条件。如果没有这些选项，默认行为是为未知编译器和版本生成 #error。

在版本 3.12 中添加: BARE_FEATURES 将使用较新语言标准中使用的名称定义兼容性宏，以便代码可以无条件地使用新功能名称。

功能测试宏

对于每个编译器，都会生成一个与 <PREFIX>_COMPILER_IS_<compiler> 匹配的预处理器宏，其内容为 0 或 1，具体取决于正在使用的编译器。为编译器版本组件生成与 <PREFIX>_COMPILER_VERSION_MAJOR <PREFIX>_COMPILER_VERSION_MINOR 和 <PREFIX>_COMPILER_VERSION_PATCH 匹配的预处理器宏，其中包含相应编译器版本组件的十进制值（如果已定义）。

基于编译器版本生成预处理器测试，指示是否启用每个功能。生成与 <PREFIX>_COMPILER_<FEATURE> 匹配的预处理器宏，其中 <FEATURE> 是大写的 <feature> 名称，以包含值 0 或 1，具体取决于正在使用的编译器是否支持该功能

write_compiler_detection_header(
  FILE climbingstats_compiler_detection.h
  PREFIX ClimbingStats
  COMPILERS GNU Clang AppleClang MSVC Intel
  FEATURES cxx_variadic_templates
)

#if ClimbingStats_COMPILER_CXX_VARIADIC_TEMPLATES
template<typename... T>
void someInterface(T t...) { /* ... */ }
#else
// Compatibility versions
template<typename T1>
void someInterface(T1 t1) { /* ... */ }
template<typename T1, typename T2>
void someInterface(T1 t1, T2 t2) { /* ... */ }
template<typename T1, typename T2, typename T3>
void someInterface(T1 t1, T2 t2, T3 t3) { /* ... */ }
#endif

符号宏

为特定功能创建了一些额外的符号定义，用作可以有条件地定义为空的符号

class MyClass ClimbingStats_FINAL
{
    ClimbingStats_CONSTEXPR int someInterface() { return 42; }
};

如果编译器（及其标志）支持 cxx_final 功能，则 ClimbingStats_FINAL 宏将展开为 final，如果支持 cxx_constexpr，则 ClimbingStats_CONSTEXPR 宏将展开为 constexpr。

如果将 BARE_FEATURES cxx_final 作为参数给出，则即使对于旧编译器，也将定义 final 关键字。

以下功能生成相应的符号定义，如果它们作为 BARE_FEATURES 可用

功能	定义	符号	裸
c_restrict	<PREFIX>_RESTRICT	restrict	是
cxx_constexpr	<PREFIX>_CONSTEXPR	constexpr	是
cxx_deleted_functions	<PREFIX>_DELETED_FUNCTION	= delete
cxx_extern_templates	<PREFIX>_EXTERN_TEMPLATE	extern
cxx_final	<PREFIX>_FINAL	final	是
cxx_noexcept	<PREFIX>_NOEXCEPT	noexcept	是
cxx_noexcept	<PREFIX>_NOEXCEPT_EXPR(X)	noexcept(X)
cxx_override	<PREFIX>_OVERRIDE	override	是

兼容性实现宏

某些功能适合包装在一个带有向后兼容性实现的宏中，如果编译器不支持该功能。

当编译器未提供 cxx_static_assert 功能时，可以通过 <PREFIX>_STATIC_ASSERT(COND) 和 <PREFIX>_STATIC_ASSERT_MSG(COND, MSG) 类函数宏获得兼容性实现。宏展开为 static_assert（如果该编译器功能可用），否则展开为兼容性实现。在第一种形式中，条件在 static_assert 的消息字段中字符串化。在第二种形式中，消息 MSG 传递给 static_assert 的消息字段，或者在使用向后兼容性实现时被忽略。

cxx_attribute_deprecated 功能提供宏定义 <PREFIX>_DEPRECATED，它展开为标准 [[deprecated]] 属性或编译器特定的装饰器，例如 GNU 编译器使用的 __attribute__((__deprecated__))。

cxx_alignas 功能提供宏定义 <PREFIX>_ALIGNAS，它展开为标准 alignas 装饰器或编译器特定的装饰器，例如 GNU 编译器使用的 __attribute__ ((__aligned__))。

cxx_alignof 功能提供宏定义 <PREFIX>_ALIGNOF，它展开为标准 alignof 装饰器或编译器特定的装饰器，例如 GNU 编译器使用的 __alignof__。

功能	定义	符号	裸
cxx_alignas	<PREFIX>_ALIGNAS	alignas
cxx_alignof	<PREFIX>_ALIGNOF	alignof
cxx_nullptr	<PREFIX>_NULLPTR	nullptr	是
cxx_static_assert	<PREFIX>_STATIC_ASSERT	static_assert
cxx_static_assert	<PREFIX>_STATIC_ASSERT_MSG	static_assert
cxx_attribute_deprecated	<PREFIX>_DEPRECATED	[[deprecated]]
cxx_attribute_deprecated	<PREFIX>_DEPRECATED_MSG	[[deprecated]]
cxx_thread_local	<PREFIX>_THREAD_LOCAL	thread_local

此类弃用宏出现的一个用例是整个库的弃用。在这种情况下，库中的所有公共 API 都可以用 <PREFIX>_DEPRECATED 宏装饰。当构建库本身时，这会导致非常嘈杂的构建输出，因此在构建已弃用的库时，可以将宏定义为空

add_library(compat_support ${srcs})
target_compile_definitions(compat_support
  PRIVATE
    CompatSupport_DEPRECATED=
)

示例用法

注意

本节从 cmake-compile-features(7) 手册迁移而来，因为它依赖于策略 CMP0120 删除的 WriteCompilerDetectionHeader 模块。

如果可用，编译功能可能是首选，而无需创建硬性要求。例如，一个库可以根据 cxx_variadic_templates 功能是否可用提供替代实现

#if Foo_COMPILER_CXX_VARIADIC_TEMPLATES
template<int I, int... Is>
struct Interface;

template<int I>
struct Interface<I>
{
  static int accumulate()
  {
    return I;
  }
};

template<int I, int... Is>
struct Interface
{
  static int accumulate()
  {
    return I + Interface<Is...>::accumulate();
  }
};
#else
template<int I1, int I2 = 0, int I3 = 0, int I4 = 0>
struct Interface
{
  static int accumulate() { return I1 + I2 + I3 + I4; }
};
#endif

这样的接口取决于为编译器功能使用正确的预处理器定义。CMake 可以使用 WriteCompilerDetectionHeader 模块生成包含此类定义的头文件。该模块包含 write_compiler_detection_header 函数，该函数接受参数来控制生成的头文件的内容

write_compiler_detection_header(
  FILE "${CMAKE_CURRENT_BINARY_DIR}/foo_compiler_detection.h"
  PREFIX Foo
  COMPILERS GNU
  FEATURES
    cxx_variadic_templates
)

这样的头文件可以在项目的源代码中内部使用，也可以安装并在库代码的接口中使用。

对于 FEATURES 中列出的每个功能，都会在头文件中创建一个预处理器定义，并定义为 1 或 0。

此外，某些功能需要额外的定义，例如 cxx_final 和 cxx_override 功能。与其在 #ifdef 代码中使用，不如使用一个符号来抽象 final 关键字，该符号定义为 final、编译器特定的等效项或为空。这样，可以编写 C++ 代码以无条件地使用该符号，而编译器支持决定了它将展开为什么

struct Interface {
  virtual void Execute() = 0;
};

struct Concrete Foo_FINAL {
  void Execute() Foo_OVERRIDE;
};

在这种情况下，如果编译器支持关键字，则 Foo_FINAL 将展开为 final，否则展开为空。

在这种用例中，项目代码可能希望在编译器可用时启用特定的语言标准。可以将目标属性 CXX_STANDARD 设置为特定目标的所需语言标准，并且可以设置变量 CMAKE_CXX_STANDARD 以影响所有后续目标

write_compiler_detection_header(
  FILE "${CMAKE_CURRENT_BINARY_DIR}/foo_compiler_detection.h"
  PREFIX Foo
  COMPILERS GNU
  FEATURES
    cxx_final cxx_override
)

# Includes foo_compiler_detection.h and uses the Foo_FINAL symbol
# which will expand to 'final' if the compiler supports the requested
# CXX_STANDARD.
add_library(foo foo.cpp)
set_property(TARGET foo PROPERTY CXX_STANDARD 11)

# Includes foo_compiler_detection.h and uses the Foo_FINAL symbol
# which will expand to 'final' if the compiler supports the feature,
# even though CXX_STANDARD is not set explicitly.  The requirement of
# cxx_constexpr causes CMake to set CXX_STANDARD internally, which
# affects the compile flags.
add_library(foo_impl foo_impl.cpp)
target_compile_features(foo_impl PRIVATE cxx_constexpr)

write_compiler_detection_header 函数还为其他具有标准等效项的功能创建兼容性代码。例如，cxx_static_assert 功能通过模板模拟，并通过 <PREFIX>_STATIC_ASSERT 和 <PREFIX>_STATIC_ASSERT_MSG 类函数宏进行抽象。