CheckStructHasMember

此模块提供了一个命令，用于检查结构体或类是否具有指定的成员变量。

在 CMake 项目中加载此模块，使用

include(CheckStructHasMember)

命令

此模块提供以下命令

check_struct_has_member

一次性检查给定的结构体或类是否具有指定的成员变量。

check_struct_has_member(
  <struct>
  <member>
  <headers>
  <variable>
  [LANGUAGE <language>]
)

此命令会在包含指定的头文件（<headers>，其中应声明原型）后，一次性检查结构体或类 <struct> 是否包含指定的 <member>。可以使用 分号分隔的列表 将多个头文件作为单个参数指定。结果将存储在内部缓存变量 <variable> 中。

选项包括

LANGUAGE <language>

使用 <language> 编译器执行检查。可接受的值为 C 和 CXX。如果未指定，则默认为 C。

影响检查的变量

在调用此命令之前，可以设置以下变量来修改检查的运行方式

CMAKE_REQUIRED_FLAGS

传递给编译器的其他标志的空格分隔字符串。 分号分隔的列表 将不起作用。 CMAKE_<LANG>_FLAGS 及其相关的特定于配置的 CMAKE_<LANG>_FLAGS_<CONFIG> 变量的内容会自动添加到编译命令之前，然后再添加此变量的内容。

CMAKE_REQUIRED_DEFINITIONS

分号分隔的编译器定义列表，每个定义的形式为 -DFOO 或 -DFOO=bar。还将自动添加对检查命令的 result variable 参数指定的名称的定义。

CMAKE_REQUIRED_INCLUDES

要传递给编译器的头文件搜索路径的分号分隔列表。这些将是唯一使用的头文件搜索路径；将忽略 INCLUDE_DIRECTORIES 目录属性的内容。

CMAKE_REQUIRED_LINK_OPTIONS

3.14 版新增。

要添加到链接命令的选项的分号分隔列表（有关更多详细信息，请参阅 try_compile()）。

CMAKE_REQUIRED_LIBRARIES

要添加到链接命令的库的分号分隔列表。这些可以是系统库的名称，也可以是 导入的目标（有关更多详细信息，请参阅 try_compile()）。

CMAKE_REQUIRED_LINK_DIRECTORIES

在版本 3.31 中添加。

要传递给链接器的库搜索路径的分号分隔列表（有关更多详细信息，请参阅 try_compile()）。

CMAKE_REQUIRED_QUIET

版本 3.1 中新增。

如果此变量评估为布尔真值，则与检查关联的所有状态消息都将被抑制。

示例

示例：检查 C 结构体成员

在下面的示例中，此模块在包含 <sys/select.h> 头文件后，检查 C 结构体 timeval 是否具有成员变量 tv_sec。检查结果将存储在内部缓存变量 HAVE_TIMEVAL_TV_SEC 中。

include(CheckStructHasMember)

check_struct_has_member(
  "struct timeval"
  tv_sec
  sys/select.h
  HAVE_TIMEVAL_TV_SEC
)

示例：检查 C++ 结构体成员

在下面的示例中，此模块在包含 <ctime> 头文件后，检查 C++ 结构体 std::tm 是否具有成员变量 tm_gmtoff。检查结果将存储在内部缓存变量 HAVE_TM_GMTOFF 中。

include(CheckStructHasMember)

check_struct_has_member(
  std::tm
  tm_gmtoff
  ctime
  HAVE_TM_GMTOFF
  LANGUAGE CXX
)

示例：使用编译定义进行隔离检查

在下面的示例中，使用 CMakePushCheckState 模块，使用临时修改的编译定义执行检查。

include(CheckStructHasMember)
include(CMakePushCheckState)

cmake_push_check_state(RESET)
  set(CMAKE_REQUIRED_DEFINITIONS -D_GNU_SOURCE)

  check_struct_has_member(
    "struct utsname"
    domainname
    sys/utsname.h
    HAVE_UTSNAME_DOMAINNAME
  )
cmake_pop_check_state()