CheckLibraryExists

此模块提供了一个命令，用于检查 C 库是否存在。

在 CMake 项目中加载此模块，使用

include(CheckLibraryExists)

命令

此模块提供以下命令

check_library_exists

检查指定的库是否存在并且给定的 C 函数是否可用

check_library_exists(<library> <function> <location> <variable>)

此命令会尝试链接一个使用指定的 C <function> 的测试可执行文件，以验证它是由系统或用户提供的 <library> 提供的。

参数为

<library>

库的名称、库文件的完整路径或 Imported Target。

<function>

在系统或用户提供的库 <library> 中应可用的函数的名称。

<location>

包含库文件的目录。它将在检查期间添加到链接搜索路径。如果这是一个空字符串，则仅使用默认库搜索路径。

<variable>

存储检查结果的变量的名称。此变量将被创建为内部缓存变量。

注意

此命令旨在执行基本的健全性检查，以验证库是否提供了预期的功能，或者是否找到了正确的库。但是，它仅验证函数符号是否可以成功链接 — 它不能确保函数在库头文件中声明，也不能检测内联函数或定义为预处理器宏的函数。要更可靠地检测函数可用性，请优先使用 CheckSymbolExists 或 CheckSourceCompiles。

影响检查的变量

在调用此命令之前，可以设置以下变量来修改检查的运行方式

CMAKE_REQUIRED_FLAGS

传递给编译器的附加标志的空格分隔字符串。一个 分号分隔的列表 将不起作用。 CMAKE_<LANG>_FLAGS 及其相关的特定于配置的 CMAKE_<LANG>_FLAGS_<CONFIG> 变量的内容会自动添加到编译器命令之前。

CMAKE_REQUIRED_DEFINITIONS

分号分隔的编译器定义列表，每个定义的形式为 -DFOO 或 -DFOO=bar。还将自动添加对检查命令的 result variable 参数指定的名称的定义。

CMAKE_REQUIRED_LINK_OPTIONS

3.14 版新增。

要添加到链接命令的选项的分号分隔列表（有关更多详细信息，请参阅 try_compile()）。

CMAKE_REQUIRED_LIBRARIES

要添加到链接命令的库的分号分隔列表。这些可以是系统库的名称，也可以是 导入的目标（有关更多详细信息，请参阅 try_compile()）。

CMAKE_REQUIRED_LINK_DIRECTORIES

在版本 3.31 中添加。

要传递给链接器的库搜索路径的分号分隔列表（有关更多详细信息，请参阅 try_compile()）。

CMAKE_REQUIRED_QUIET

版本 3.1 中新增。

如果此变量评估为布尔真值，则与检查关联的所有状态消息都将被抑制。

示例

检查 curl 库是否在默认路径中存在，以及是否具有 curl_easy_perform() 函数

include(CheckLibraryExists)
check_library_exists(curl curl_easy_perform "" HAVE_LIBRARY_CURL)

检查库是否在特定的非标准位置存在，以及是否具有指定的函数

include(CheckLibraryExists)
check_library_exists(curl curl_easy_perform "/opt/curl/lib" HAVE_LIBRARY_CURL)

还可以使用 Imported Targets（例如，来自 find_package() 调用）

find_package(CURL)

# ...

if(TARGET CURL::libcurl)
  include(CheckLibraryExists)
  check_library_exists(CURL::libcurl curl_easy_perform "" HAVE_LIBRARY_CURL)
endif()

另请参阅